Есть ли способ обойти все элементы на веб-странице HTML с помощью VBScript?

Question

Есть ли способ обойти все элементы на веб-странице HTML с помощью VBScript? Например, я хочу получить всю информацию об объекте на веб-странице html: http://www.echoecho.com/html.htm

Вот скрипт, который я создал, спасибо:

Dim objIE 
Dim IEObject
Dim Info
Info = “”

Set objIE = CreateObject("InternetExplorer.Application")
objIE.Visible = True
objIE.Navigate "http://www.echoecho.com/html.htm"

Do While objIE.Busy Or (objIE.READYSTATE <> 4)
   Wscript.Sleep 100
Loop
WScript.Sleep 50

‘ Can I use objIE.Document.all.Item.length to count all elements on the webpage?
For i=1 to objIE.Document.all.Item.length then

   IEObject = objIE.Document..??????... item (i-1)…???
   Info = Info & vbCrLf & i & IEObject.id & “-“IEObject.title & “-“ & IEObject.name & “-“ & ….etc.

Next

Wscript.Echo Info

Set IEObject = Nothing
Set objIE = Nothing

Answer 1

Ваш вопрос был немного расплывчатым, но я верю, что это поможет:

Dim objIE, IEObject, Info, all, hasOwnProperty
Info = ""

Set objIE = CreateObject("InternetExplorer.Application")
objIE.Visible = True
objIE.Navigate "http://www.echoecho.com/html.htm"

Do While objIE.Busy Or (objIE.READYSTATE <> 4)
 Wscript.Sleep 100
Loop
WScript.Sleep 50

Set hasOwnProperty = objIE.Document.ParentWindow.Object.prototype.hasOwnProperty

' Can I use objIE.Document.all.Item.length to count all elements on the webpage?
Set all = objIE.Document.all
For i = 0 To all.Item.Length - 1
Set IEObject = all.Item(i)

'If this is not the first item, place this data on a new line.
If i > 0 Then Info = Info & vbCrLf

' Number each line.
Info = Info & i + 1 & ". "

' Specify the ID if it is given.
If hasOwnProperty.call(IEObject, "id") Then
  Info = Info & IEObject.id
Else
  Info = Info & "[NO ID]"
End If

' Specify the title if it is given.
If hasOwnProperty.call(IEObject, "title") Then
  Info = Info & "-" & IEObject.title
Else
  Info = Info & "-[NO TITLE]"
End If

' Specify the name if it is given.
If hasOwnProperty.call(IEObject, "name") Then
  Info = Info & "-" & IEObject.name
Else
  Info = Info & "-[NO NAME]"
End If
Next

Wscript.Echo Info

Set IEObject = Nothing
Set objIE = Nothing

Вы заметите, что я использую функцию hasOwnProperty, чтобы проверить, существует ли указанное свойство для данного элемента. Без этой проверки ошибки будут возникать в VBScript, но не в JScript.