Почему мой Perl-скрипт возвращает нулевой код возврата, когда я явно вызываю exit с ненулевым параметром? - PullRequest
Новая
       20

Почему мой Perl-скрипт возвращает нулевой код возврата, когда я явно вызываю exit с ненулевым параметром?

8 голосов
/ 21 апреля 2010

У меня есть скрипт Perl, который вызывает другой скрипт. Скрипт Perl должен распространять код возврата скрипта, но, похоже, он возвращает ноль своему вызывающему (Java-приложение) явному вызову exit $scriptReturnCode.

Код и вывод следующим образом (я понимаю, что <=> может / должно быть !=, но это то, что у меня есть): 

print "INFO: Calling ${scriptDirectory}/${script} ${args}"
$scriptReturnCode = system("${scriptDirectory}/${script} ${args}");

if ( $scriptReturnCode <=> 0 ) {
        print "ERROR: The script returned $scriptReturnCode\n";
        exit $scriptReturnCode;
} else {
        print "INFO: The script returned $scriptReturnCode.\n";
        exit 0;
}

Вывод из моего Java: 

20/04/2010 14:40:01 - INFO: Calling /path/to/script/script.ksh arg1 arg2 
20/04/2010 14:40:01 - Could not find installer files <= this is from the script.ksh    
20/04/2010 14:40:01 - ERROR: The script returned 256
20/04/2010 14:40:01 - Command Finished. Exit Code: 0 <= this is the Java app.

Ответы [ 2 ]

10 голосов
/ 21 апреля 2010

Вам необходимо перевести код возврата из system() вызова на 8 бит.

например. $exit_value = $? >> 8; # В вашем скрипте $? равно $ scriptReturnCode

С http://perldoc.perl.org/perlfaq8.html:

system() запускает команду и возвращает информацию о состоянии выхода (как 16-битное значение: младшие 7 битов - это сигнал, от которого умер процесс, если таковые имеются, а старшие 8 битов - фактическое значение выхода

Более расширенная проверка кода для coredumps также может выглядеть следующим образом: 

system();
if ($? == -1) {
    print "failed to execute: $!\n";
} elsif ($? & 127) {
    printf "child died - signal %d, %s coredump\n",
           ($? & 127), ($? & 128) ? 'with' : 'without';
} else {
    printf "child exited with value %d\n", $? >> 8;
}

ОБНОВЛЕНИЕ: согласно отличному напоминанию ysth, коды выхода усекаются до 8 (младших) битов, поэтому возвращение 256 вместо предполагаемого 1 заканчивается как 0. Аналогично, возвращение 257 заканчивается как 1.

1 голос
/ 21 апреля 2010

Если перехват $? и смещение его значения слишком сложны для запоминания, вы можете упростить этот код, используя IPC :: System :: Simple , что повышает system() и обратные пометки с большей ошибкой проверка и диагностика, например: 

use IPC::System::Simple qw(run EXIT_ANY);

my $command = "${scriptDirectory}/${script} ${args}";
print "INFO: Calling $command\n";

# runs command through a shell first; does not die on any exit value
run(EXIT_ANY, $command);
my $scriptReturnCode = $IPC::System::Simple::EXITVAL;
...