Как я могу узнать, выдавал ли Log4perl какие-либо предупреждения во время пробега? - PullRequest
Новая
       1

Как я могу узнать, выдавал ли Log4perl какие-либо предупреждения во время пробега?

6 голосов
/ 06 апреля 2010

Я использовал Log4perl в ряде сценариев. Я хотел бы дополнить эти сценарии, чтобы установить код ошибки, если какие-либо сообщения WARN или ERROR были зарегистрированы. Я не смог найти очевидного способа сделать это на основе существующей документации.

Я бы хотел избежать переписывания моих существующих сценариев методом грубой силы, чтобы добавить проверку для каждого сообщения журнала WARN или ERROR; Я предпочел бы обработать это до выхода из скрипта, если это возможно, как этот псевдокод: 

if $log->has_warnings_or_errors then
  exit 1
else
  exit 0

Есть ли какой-нибудь простой способ вызвать Log4Perl, чтобы определить, есть ли у текущего регистратора сообщения определенных уровней?

Ответы [ 2 ]

6 голосов
/ 06 апреля 2010

Использовать appender .

MyCounter.pm: 

package MyCounter;

use warnings;
use strict;

use Log::Log4perl::Level;

sub new {
  my($class,%arg) = @_;
  bless {} => $class;
}

sub log {
  my($self,%arg) = @_;
  ++$self->{ $arg{log4p_level} };
}

sub howmany {
  my($self,@which) = @_;
  my $total = 0;
  $total += ($self->{$_} || 0) for @which;
  $total;
}

1;

MyProg: 

#! /usr/bin/perl

use warnings;
use strict;

use Log::Log4perl;

my $conf = q(
  log4perl.category.MyLogger = INFO, Screen

  log4perl.appender.Screen = Log::Log4perl::Appender::Screen
  log4perl.appender.Screen.layout = Log::Log4perl::Layout::SimpleLayout
);

Log::Log4perl->init(\$conf);

my $l = Log::Log4perl->get_logger("MyLogger");

my $counter = Log::Log4perl::Appender->new("MyCounter");
$l->add_appender($counter);

$l->warn("warning");
$l->info("info");
$l->error("incorrect");
$l->fatal("really bad, man");

print $counter->howmany(qw/ WARN ERROR FATAL /), "\n";

exit ($counter->howmany(qw/ WARN ERROR FATAL /) ? 1 : 0);

Выход: 

$ ./myprog 
WARN - warning
INFO - info
ERROR - incorrect
FATAL - really bad, man
3
$ echo $?
1

Закомментируйте строки ...->warn, ...->error и ...->fatal, чтобы получить 

$ ./myprog 
INFO - info
0
$ echo $?
0
0 голосов
/ 06 апреля 2010

Вы можете использовать обертку и писать собственные методы fatal, error и warn, которые увеличивают счетчик, и метод доступа, который возвращает значение этого счетчика.

...