Как я могу получить пользовательский ввод, не дожидаясь ввода в Perl?

Question

Я пытаюсь сделать интерактивный скрипт на Perl.

Единственный пользовательский ввод, который я могу найти, следующий:

 $name = <STDIN>;
 print STDOUT "Hello $name\n";

Но при этом пользователь должен всегда нажимать ввод, чтобы изменения вступили в силу. Как заставить программу работать сразу после нажатия кнопки?

Answer 1

От ответа perlfaq8 на Как прочитать только один ключ, не ожидая возврата?:

---

Управление входной буферизацией в значительной степени зависит от системы.Во многих системах вы можете просто использовать команду stty, как показано в getc в perlfunc, но, как вы видите, это уже вводит вас в трудности переносимости.

open(TTY, "+</dev/tty") or die "no tty: $!";
system "stty  cbreak </dev/tty >/dev/tty 2>&1";
$key = getc(TTY);       # perhaps this works
# OR ELSE
sysread(TTY, $key, 1);  # probably this does
system "stty -cbreak </dev/tty >/dev/tty 2>&1";

Модуль Term :: ReadKey из CPAN предлагаетпростой в использовании интерфейс, который должен быть более эффективным, чем выделение stty для каждого ключа.Он даже включает ограниченную поддержку Windows.

use Term::ReadKey;
ReadMode('cbreak');
$key = ReadKey(0);
ReadMode('normal');

Однако для использования кода требуется наличие работающего компилятора C, который можно использовать для сборки и установки модуля CPAN.Вот решение с использованием стандартного модуля POSIX, который уже есть в вашей системе (при условии, что ваша система поддерживает POSIX).

use HotKey;
$key = readkey();

А вот модуль HotKey, который скрывает несколько загадочных вызовов для управления структурами termos POSIX.

# HotKey.pm
package HotKey;

@ISA = qw(Exporter);
@EXPORT = qw(cbreak cooked readkey);

use strict;
use POSIX qw(:termios_h);
my ($term, $oterm, $echo, $noecho, $fd_stdin);

$fd_stdin = fileno(STDIN);
$term     = POSIX::Termios->new();
$term->getattr($fd_stdin);
$oterm     = $term->getlflag();

$echo     = ECHO | ECHOK | ICANON;
$noecho   = $oterm & ~$echo;

sub cbreak {
    $term->setlflag($noecho);  # ok, so i don't want echo either
    $term->setcc(VTIME, 1);
    $term->setattr($fd_stdin, TCSANOW);
}

sub cooked {
    $term->setlflag($oterm);
    $term->setcc(VTIME, 0);
    $term->setattr($fd_stdin, TCSANOW);
}

sub readkey {
    my $key = '';
    cbreak();
    sysread(STDIN, $key, 1);
    cooked();
    return $key;
}

END { cooked() }

1;

Answer 2

Вы можете использовать модуль Term :: ReadKey для проверки нажатия клавиши.