Проблема извлечения времени из поля даты в хранимой процедуре оракула - PullRequest
Новая
       10

Проблема извлечения времени из поля даты в хранимой процедуре оракула

0 голосов
/ 02 февраля 2010

У меня проблемы с получением времени из поля даты в SP.Если я выполню запрос: 

select TO_CHAR(HOR_HST_ATN,'YYYY/MM/DD HH24:MI:SS') AS HOR_HST_ATN FROM AAM0_DT_RSTCN ;

Он возвращает дату и время в порядке.

Но в SP код: 

SELECT   FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, NOM_SEM_HST_ATN, 
    TO_DATE(HOR_DSD_ATN ,'DD/MM/YYYY HH24:MI:SS') as  HOR_DSD_ATN,
    TO_DATE(HOR_HST_ATN,'DD/MM/YYYY HH24:MI:SS') as HOR_HST_ATN

возвращает только датухорошо, но время 00: 00

Если я пытаюсь выбрать в SP с TO_CHAR, как в: 

SELECT   FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, NOM_SEM_HST_ATN,
 TO_CHAR(HOR_DSD_ATN ,'YYYY/MM/DD HH24:MI:SS') as  HOR_DSD_ATN,
 TO_CHAR(HOR_HST_ATN,'YYYY/MM/DD HH24:MI:SS') as HOR_HST_ATN

Я получаю ошибку: SQLCODE: -6502 SQLERRM:ORA-06502: PL / SQL: ошибка ...

Есть какие-нибудь подсказки?Кстати, я должен использовать SP, чтобы получить это значение.

Обновление: столбец тип даты.Вот полный SP: 

FUNCTION FN_AAM_EV_RSTCN ( 

I_NUM_CONTRATO            IN  AAM0_DT_RSTCN.NUM_CONTRATO%TYPE,
I_COD_PFL                  IN  AAM0_DT_RSTCN.COD_PFL%TYPE, 
I_COD_APL_PFM              IN  AAM0_DT_RSTCN.COD_APL_PFM%TYPE, 
I_COD_PTO                  IN  AAM0_DT_RSTCN.COD_PTO%TYPE, 
I_COD_FNC                  IN  AAM0_DT_RSTCN.COD_FNC%TYPE
) RETURN BOOLEAN
AS
T_FEC_DSD_ATN                   AAM0_DT_RSTCN.FEC_DSD_ATN%TYPE;
T_HOR_DSD_ATN                   AAM0_DT_RSTCN.HOR_DSD_ATN%TYPE;
T_FEC_HST_ATN                   AAM0_DT_RSTCN.FEC_HST_ATN%TYPE;
T_HOR_HST_ATN                   AAM0_DT_RSTCN.HOR_HST_ATN%TYPE;
T_NOM_SEM_DSD_ATN               AAM0_DT_RSTCN.NOM_SEM_DSD_ATN%TYPE;
T_NOM_SEM_HST_ATN               AAM0_DT_RSTCN.NOM_SEM_HST_ATN%TYPE;

 O_RESULTSET2          REST_REFCUR;

BEGIN
 OPEN O_RESULTSET2 FOR 

   SELECT   FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, NOM_SEM_HST_ATN, 
    TO_CHAR(HOR_DSD_ATN ,'DD/MM/YYYY HH24:MI:SS') as  HOR_DSD_ATN,
    TO_CHAR(HOR_HST_ATN,'DD/MM/YYYY HH24:MI:SS') as HOR_HST_ATN
    FROM    AAM0_DT_RSTCN
    WHERE ROWNUM <=1
    AND   NUM_CONTRATO          = NVL ( I_NUM_CONTRATO, NUM_CONTRATO )
    AND     COD_PFL               = NVL ( I_COD_PFL, COD_PFL )
    AND     COD_APL_PFM           = NVL ( I_COD_APL_PFM, COD_APL_PFM )
    AND     COD_PTO               = NVL ( I_COD_PTO, COD_PTO )
    AND     COD_FNC               = NVL ( I_COD_FNC, COD_FNC )    
    AND     FLG_RCS               = 'D'
    AND     COD_TPO_CDC           = 'PC'
    ;

   FETCH O_RESULTSET2 INTO T_FEC_DSD_ATN, T_FEC_HST_ATN, T_NOM_SEM_DSD_ATN, T_NOM_SEM_HST_ATN, T_HOR_DSD_ATN, T_HOR_HST_ATN ;

  IF (O_RESULTSET2%NOTFOUND) THEN
    RETURN TRUE;
  ELSE
   dbms_output.put_line('EVALUO RESTRICCIONES: T_FEC_DSD_ATN '  || T_FEC_DSD_ATN || ' T_FEC_HST_ATN : ' || T_FEC_HST_ATN || ' T_NOM_SEM_DSD_ATN: ' ||
                 T_NOM_SEM_DSD_ATN || ' T_NOM_SEM_HST_ATN: '  || T_NOM_SEM_HST_ATN || ' T_HOR_DSD_ATN: ' || TO_CHAR(T_HOR_DSD_ATN ,'DD/MM/YYYY HH24:MI:SS')  || 
                ' T_HOR_HST_ATN: ' || TO_CHAR(T_HOR_HST_ATN ,'DD/MM/YYYY HH24:MI:SS') );

     IF (NOT((T_FEC_DSD_ATN IS NULL) and (T_FEC_HST_ATN IS NULL)) ) THEN

       IF ( NOT ((T_FEC_DSD_ATN  <= SYSDATE) AND (T_FEC_HST_ATN >= SYSDATE ))) THEN
                RETURN FALSE;
        END IF ;

    END IF ;

  RETURN TRUE;

  END IF ;

EXCEPTION

  WHEN NO_DATA_FOUND THEN
    RETURN TRUE; 

  WHEN OTHERS THEN


    IF O_RESULTSET2%ISOPEN THEN

      CLOSE O_RESULTSET2;

    END IF;


    DBMS_OUTPUT.PUT_LINE('ERROR en FN_AAM_EV_RSTCN : '); 
    DBMS_OUTPUT.PUT_LINE('  SQLCODE: ' || SQLCODE );
    DBMS_OUTPUT.PUT_LINE('  SQLERRM: ' || SQLERRM );

    ROLLBACK;

 END FN_AAM_EV_RSTCN;

Ответы [ 4 ]

3 голосов
/ 03 февраля 2010

Ваша проблема заключается в следующем коде: 

...
T_HOR_DSD_ATN                   AAM0_DT_RSTCN.HOR_DSD_ATN%TYPE;
T_HOR_HST_ATN                   AAM0_DT_RSTCN.HOR_HST_ATN%TYPE;
...
SELECT   FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, NOM_SEM_HST_ATN, 
TO_CHAR(HOR_DSD_ATN ,'DD/MM/YYYY HH24:MI:SS') as  HOR_DSD_ATN,
TO_CHAR(HOR_HST_ATN,'DD/MM/YYYY HH24:MI:SS') as HOR_HST_ATN
FROM    AAM0_DT_RSTCN
...
FETCH O_RESULTSET2 INTO T_FEC_DSD_ATN, T_FEC_HST_ATN, T_NOM_SEM_DSD_ATN,
T_NOM_SEM_HST_ATN, T_HOR_DSD_ATN, T_HOR_HST_ATN ;

Поскольку столбцы HOR_DSD_ATN и HOR_HST_ATN имеют тип данных DATE, ваши локальные переменные (T_HOR_DSD_ATN и T_HOR_HST_ATN) также являются датами. Однако в вашем SELECT вы конвертируете эти даты в строки с помощью функции TO_CHAR. Таким образом, ваш выбор эффективно делает это (я составил несколько дат здесь): 

T_HOR_DSD_ATN := '03/02/2010 09:33:30';
T_HOR_HST_ATN := '01/01/2010 12:30:00';

Поскольку вы присваиваете строку переменной даты, Oracle должен сделать неявный TO_DATE - поэтому он использует NLS_DATE_FORMAT сеанса для их преобразования, который, вероятно, просто получает часть даты (например, DD/MM/YYYY) и теряет значения времени .

Чтобы исправить это, просто удалите TO_CHAR () из вашего оператора SELECT - таким образом вы получите значения даты и времени, не измененные в ваших локальных переменных.

2 голосов
/ 02 февраля 2010

Поскольку функция TO_DATE принимает VARCHAR в качестве аргумента, вы не будете использовать эту функцию в поле DATE. Если вы хотите получить как дату, так и время из поля DATE, вам просто нужно выбрать поля без функций: 

SELECT   FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, NOM_SEM_HST_ATN, 
         HOR_DSD_ATN, HOR_HST_ATN
   ...

обновление

Проблема в том, что вы извлекаете TO_CHAR(HOR_DSD_ATN, 'DD/MM/YYYY HH24:MI:SS') в поле DATE. Существует неявное преобразование, которое усекает вашу дату. Используйте to_char для переменной DATE и to_date для переменной CHAR.

Мое предложение: 

FUNCTION FN_AAM_EV_RSTCN(I_NUM_CONTRATO IN AAM0_DT_RSTCN.NUM_CONTRATO%TYPE,
                         I_COD_PFL      IN AAM0_DT_RSTCN.COD_PFL%TYPE,
                         I_COD_APL_PFM  IN AAM0_DT_RSTCN.COD_APL_PFM%TYPE,
                         I_COD_PTO      IN AAM0_DT_RSTCN.COD_PTO%TYPE,
                         I_COD_FNC      IN AAM0_DT_RSTCN.COD_FNC%TYPE) 
   RETURN BOOLEAN AS
BEGIN
   FOR cc IN (SELECT FEC_DSD_ATN, FEC_HST_ATN, NOM_SEM_DSD_ATN, 
                     NOM_SEM_HST_ATN, HOR_DSD_ATN, HOR_HST_ATN
                FROM AAM0_DT_RSTCN
               WHERE ROWNUM <= 1
                 AND NUM_CONTRATO = NVL(I_NUM_CONTRATO, NUM_CONTRATO)
                 AND COD_PFL = NVL(I_COD_PFL, COD_PFL)
                 AND COD_APL_PFM = NVL(I_COD_APL_PFM, COD_APL_PFM)
                 AND COD_PTO = NVL(I_COD_PTO, COD_PTO)
                 AND COD_FNC = NVL(I_COD_FNC, COD_FNC)
                 AND FLG_RCS = 'D'
                 AND COD_TPO_CDC = 'PC') LOOP
      dbms_output.put_line(' T_HOR_DSD_ATN: ' || 
                           TO_CHAR(cc.HOR_DSD_ATN, 'DD/MM/YYYY HH24:MI:SS') ||
                           ' T_HOR_HST_ATN: ' || 
                           TO_CHAR(cc.HOR_HST_ATN, 'DD/MM/YYYY HH24:MI:SS'));
      -- your logic with return boolean
   END LOOP;
   -- no rows found
   RETURN TRUE;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE('ERROR en FN_AAM_EV_RSTCN : ');
      DBMS_OUTPUT.PUT_LINE('  SQLCODE: ' || SQLCODE);
      DBMS_OUTPUT.PUT_LINE('  SQLERRM: ' || SQLERRM);
      RAISE;
END FN_AAM_EV_RSTCN;
0 голосов
/ 02 февраля 2010

Если столбцы заполнены датами без элемента времени, Oracle по умолчанию устанавливает время до полуночи ... 

SQL> create table t23 (d date)
  2  /

Table created.

SQL> insert into t23 values (sysdate)
  2  /

1 row created.

SQL> insert into t23 values (to_date('03-FEB-2010', 'DD-MON-YYYY'))
  2  /

1 row created.

SQL> select to_char(d, 'DD/MM/YYYY HH24:MI:SS') as datetime from t23
  2  /

DATETIME
-------------------
02/02/2010 17:59:51
03/02/2010 00:00:00

SQL>
0 голосов
/ 02 февраля 2010

Если HOR_HST_ATN является столбцом даты, тогда TO_DATE(HOR_HST_ATN,'DD/MM/YYYY HH24:MI:SS') должно быть опечаткой. Вы, вероятно, имеете в виду TO_CHAR ().

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...