Пользовательские классы ActionScript: синтаксический сахар - PullRequest
Новая
       5

Пользовательские классы ActionScript: синтаксический сахар

1 голос
/ 05 марта 2010

Из-за некоторых ограничений ( пример ) во встроенном классе ActionScript 3 Dictionary я собираюсь создать оболочку, которая добавляет такие вещи.Можно ли сохранить приведенный ниже синтаксис для моего пользовательского класса, и если да, то как? 

var dic:MyDic = new MyDic();
dic[stuffy] = someObject;

1 Ответ

2 голосов
/ 05 марта 2010

Да, вы можете использовать функцию Proxy , но с потерей производительности: 

import flash.utils.Dictionary;
import flash.utils.Proxy;
import flash.utils.flash_proxy;

public class MyDict extends Proxy {
    private var _size:int = 0;
    private var _dict:Dictionary = new Dictionary();

    public function get size():int {
        return _size;
    }

    flash_proxy override function getProperty(name:*):* {
        return _dict[name];
    }

    flash_proxy override function setProperty(name:*, value:*):void {
        if (!_dict.hasOwnProperty(name))
            _size ++;
        _dict[name] = value;
    }

    flash_proxy override function deleteProperty(name:*):Boolean {
        if (_dict.hasOwnProperty(name)) {
            _size --;
            delete _dict[name];
            return true;
        }
        return false;
    }
}

var dict:MyDict = new MyDict();
dict[1] = 2;
dict["foo"] = "bar";
trace(dict.size, dict[1], dict["foo"]);

delete dict[1];
trace(dict.size, dict[1], dict["foo"]);
...