атрибуты xsl: element apply - PullRequest
Новая
       7

атрибуты xsl: element apply

1 голос
/ 18 января 2010

этот вопрос относится к

XSLT для генерации HTML-тегов, указанных в XML

где у меня был документ xml и я использовал xsl для генерации тегов html, используя 

<xsl:element name="{Type}" >

проблема в том, что я хочу указать некоторые атрибуты html в моем xml, например 

<Page>
  <ID>Site</ID>
  <Object>
    <ID>PostCode</ID>
    <Type>div</Type>
    <Attributes>
       <Attribute name="class">TestStyle</Attribute>
       <Attribute name="id">TestDiv</Attribute>
    </Attributes>
    <Class>display-label</Class>
    <Value>PostCode</Value>
  </Object>
</Page>

Так кто-нибудь знает, как я мог бы заполнить элемент xsl: двумя атрибутами с помощью xsl?

Спасибо

Ответы [ 3 ]

4 голосов
/ 18 января 2010

Построение из таблицы стилей , которую я разместил в предыдущем вопросе , в объявлении element вы можете перебирать каждый из элементов Attributes/Attribute и создавать атрибуты для элемента , который вы создаете.

Вы "стоите" на узле элемента Object внутри этого цикла for, поэтому вы можете перебирать его элементы Attributes/Attribute следующим образом: 

<xsl:for-each select="Attributes/Attribute">
  <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
</xsl:for-each>

Применительно к вашей таблице стилей: 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:for-each select="Page/Object">
            <xsl:element name="{Type}" >
                <xsl:for-each select="Attributes/Attribute">
                    <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
                </xsl:for-each>
                <xsl:value-of select="Value"/>
            </xsl:element>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

Это альтернативный способ достижения того же результата, но немного более деликатно, с использованием apply-templates вместо for-each. 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:apply-templates select="Page/Object" />
      </body>
    </html>
  </xsl:template>

  <xsl:template match="Object">
    <xsl:element name="{Type}" >
       <xsl:apply-templates select="Attributes/Attribute" />
       <xsl:apply-templates select="Value" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="Attribute">
     <xsl:attribute name="{@name}"><xsl:value-of select="."/></xsl:attribute>
  </xsl:template>

</xsl:stylesheet>
2 голосов
/ 18 января 2010

Вам нужно исправить элемент Attributes в исходном образце, он не закрыт.

Вы можете использовать xsl:for-each или xsl:apply-templates с select="Attributes/Attribute", чтобы вызвать элемент xsl:attribute, который выглядит примерно так: 

<xsl:attribute name="{@name}"><xsl:value-of select="text()"/></xsl:attribute>

Вам нужно остерегаться того, что xsl:attribute должен предшествовать чему-либо, что добавляет потомков к элементу {Type}.

1 голос
/ 18 января 2010 
<xsl:element name="Attribute">
  <xsl:attribute name="class">TestStyle</xsl:attribute>
  <xsl:attribute name="id">TestDiv</xsl:attribute>
</xsl:element>
...