Доступ к веб-сервису из хранимой процедуры Oracle

Question

Есть ли кто-нибудь, кто успешно получил доступ к веб-сервису из хранимой процедуры Oracle? Если да, то была ли это хранимая процедура Java? Хранимая процедура PL / SQL?

Есть ли причина, по которой я не должен пытаться получить доступ к WS из хранимого процесса?

Вот пара ссылок, которые я нашел до сих пор

• Веб-службы базы данных
• Вызов внешней веб-службы из хранимой процедуры Java

.. Просто чтобы уточнить, это для вызовов SOAP

Answer 1

Во-первых, какой веб-сервис вы звоните? Я предполагаю, что мыло или отдых.

Для веб-служб REST UTL_HTTP часто более чем достаточно в сочетании с небольшим количеством XPath в простой хранимой процедуре PL / SQL.

Для веб-сервисов SOAP это зависит от того, насколько сложным вы должны (или хотите) быть. Вы, безусловно, можете использовать XQuery для создания XML-документа, который соответствует спецификации веб-службы, использовать UTL_HTTP для публикации документа и получения ответа, а затем использовать XPath для анализа всего ответа в PL / SQL. Это относительно ручное и относительно грубое решение, но если вы говорите о небольшом количестве веб-сервисов, оно подразумевает минимум инфраструктуры, и вызовы могут быть довольно быстро собраны воедино.

Если вы ожидаете, что вызовы будут развиваться с течением времени, или вы ожидаете, что будет ряд процедур, вызывающих несколько веб-сервисов, вероятно, имеет смысл потратить время на что-то вроде UTL_DBWS (хотя это не то вы обычно работаете через пару часов).

Answer 2

Довольно просто обернуть UTL_HTTP в удобную функцию:

FUNCTION post
(
    p_url     IN VARCHAR2,
    p_data    IN CLOB,
    p_timeout IN BINARY_INTEGER DEFAULT 60
) 
    RETURN CLOB
IS
    --
    v_request  utl_http.req;
    v_response utl_http.resp;
    v_buffer   CLOB;
    v_chunk    VARCHAR2(4000);
    v_length   NUMBER;
    v_index    NUMBER;
BEGIN

    v_index := 1;
    v_length := nvl(length(p_data), 0);

    -- configure HTTP
    utl_http.set_response_error_check(enable => FALSE);
    utl_http.set_detailed_excp_support(enable => FALSE);
    utl_http.set_transfer_timeout(p_timeout);

    -- send request
    v_request := utl_http.begin_request(p_url, 'POST','HTTP/1.0');
    utl_http.set_header(v_request, 'Content-Type', 'text/xml');
    utl_http.set_header(v_request, 'Content-Length', v_length);
    WHILE v_index <= v_length LOOP
        utl_http.write_text(v_request, substr(p_data, v_index, 4000));
        v_index := v_index + 4000;
    END LOOP;

    -- check HTTP status code for error
    IF v_response.status_code <> utl_http.http_ok THEN   
        raise_application_error(
            cn_http_error,
            v_response.status_code || ' - ' || v_response.reason_phrase
        );
    END IF;

    -- get response
    dbms_lob.createtemporary(v_buffer, FALSE);
    v_response := utl_http.get_response(v_request);
    BEGIN
        LOOP
            utl_http.read_text(v_response, v_chunk, 4000);
            dbms_lob.writeappend(v_buffer, length(v_chunk), v_chunk);
        END LOOP;
    EXCEPTION
        WHEN utl_http.end_of_body THEN NULL;
    END;
    utl_http.end_response(v_response);

    RETURN v_buffer;

END;

Тогда вам просто нужно что-то ПОСТАВИТЬ SOAP-конверт:

FUNCTION invoke
(
    p_url IN VARCHAR2,
    p_method IN XMLTYPE,
    p_timeout IN NUMBER := 60
)
    RETURN XMLTYPE
IS
    -- calls the given SOAP service
    cn_procedure_name CONSTANT VARCHAR2(30) := 'invoke';
    --
    v_envelope XMLTYPE;
    v_response CLOB;
    v_fault XMLTYPE;
    v_sqlerrm VARCHAR2(2000);
BEGIN

    -- wrap method in SOAP envelope
    SELECT
        XMLElement(
            "soap:Envelope",
            XMLAttributes(
                'http://schemas.xmlsoap.org/soap/envelope/' AS "xmlns:soap"
            ),
            XMLElement(
                "soap:Body",
                p_method
            )
        )
    INTO
        v_envelope
    FROM
        dual;

    -- POST request
    v_response := post(
        p_url,
        '<?xml version="1.0" encoding="ISO-8859-1"?>' || chr(10) || v_envelope.getClobVal(),
        p_timeout
    );
    IF v_response IS NULL THEN
        RAISE null_response;
    END IF;

    -- parse response
    BEGIN
        v_envelope := XMLType(v_response);
    EXCEPTION
        WHEN OTHERS THEN
            v_sqlerrm := SQLERRM;
            RAISE xml_parse_error;
    END;

    -- check for a fault
    v_fault := v_envelope.extract(  
        '/soap:Envelope/soap:Body/soap:Fault', 
        'xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"'
    );
    IF v_fault IS NOT NULL THEN
        v_sqlerrm := v_fault.extract('.//faultstring/text()').getStringVal();
        RAISE soap_fault;
    END IF;

    -- the actual response is the child of the <soap:Body /> element
    RETURN v_envelope.extract(
        '/soap:Envelope/soap:Body/*[position() = 1]', 
        'xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"'
    );

END;

Обратите внимание, что я удалил наш блок обработки исключений, поскольку он не имеет особого отношения к примеру.

При этом вы можете заставить любую другую процедуру сгенерировать XML, необходимый для вызова службы, передать его через invoke и проанализировать возвращаемое значение.

Мы разработали это решение для базы данных 9i, поэтому мы еще не изучали UTL_DBWS. Хотя он прекрасно работает.