у меня нормально работает:
declare @TableName table (id int,Description varchar(50))
insert @TableName values (1,'aaa')
insert @TableName values (2,'bbb')
insert @TableName values (3,'ccc')
insert @TableName values (4,'ddd')
insert @TableName values (5,'eee')
insert @TableName values (6,'fff')
insert @TableName values (7,'ggg')
insert @TableName values (8,'hhh')
DECLARE @Order varchar(10)
,@ID int
,@Description varchar(50)
,@StartIndex int
,@Count int
SELECT @Order='Description desc'
,@StartIndex=2
,@Count=3
--query unchanged, except alias to "t" and table name to "@TableName"
Select * from
(
Select ROW_NUMBER() OVER
(Order By
case
when @Order = 'ID asc' then t.ID
when @Order = 'Description asc' then t.Description
end asc,
case
when @Order = 'ID desc' then t.ID
when @Order = 'Description desc' then t.Description
end desc
) as row,
t.* from @TableName t
where
(@ID IS NULL OR t.ID = @ID) AND
(@Description IS NULL OR t.Description = @Description)
) as a
where
row > @StartIndex
and (@Count is null or row <= @StartIndex + @Count)
order by
case
when @Order = 'ID asc' then a.ID
when @Order = 'Description asc' then a.Description
end asc,
case
when @Order = 'ID desc' then a.ID
when @Order = 'Description desc' then a.Description
end desc
выход:
row id Description
-------------------- ----------- -------------
3 3 ccc
4 4 ddd
5 5 eee
(3 row(s) affected)
возможно, опубликуйте более подробную информацию о данных, с которыми вы работаете, и фактическое сообщение об ошибке.
РЕДАКТИРОВАТЬ на основе комментария ОП, попробуйте это:
declare @TableName table (id int,Description varchar(50))
insert @TableName values (1,'1')
insert @TableName values (2,'bbb')
insert @TableName values (3,'ccc')
insert @TableName values (4,'ddd')
insert @TableName values (5,'eee')
insert @TableName values (6,'fff')
insert @TableName values (7,'ggg')
insert @TableName values (8,'hhh')
DECLARE @Order varchar(50)
,@ID int
,@Description varchar(50)
,@StartIndex int
,@Count int
SELECT @Order='Description desc'
,@StartIndex=2
,@Count=3
Select * from
(
Select ROW_NUMBER() OVER
(Order By
case
when @Order = 'ID asc' then RIGHT(REPLICATE('0',10)+CONVERT(varchar(10),t.ID),10)
when @Order = 'Description asc' then t.Description
end asc,
case
when @Order = 'ID desc' then RIGHT(REPLICATE('0',10)+CONVERT(varchar(10),t.ID),10)
when @Order = 'Description desc' then t.Description
end desc
) as row,
t.* from @TableName t
where
(@ID IS NULL OR t.ID = @ID) AND
(@Description IS NULL OR t.Description = @Description)
) as a
where
row > @StartIndex
and (@Count is null or row <= @StartIndex + @Count)
order by
case
when @Order = 'ID asc' then RIGHT(REPLICATE('0',10)+CONVERT(varchar(10),a.ID),10)
when @Order = 'Description asc' then a.Description
end asc,
case
when @Order = 'ID desc' then RIGHT(REPLICATE('0',10)+CONVERT(varchar(10),a.ID),10)
when @Order = 'Description desc' then a.Description
end desc
Я в основном конвертирую идентификаторы в строки, используя эту логику:
RIGHT(REPLICATE('0',10)+CONVERT(varchar(10),ID),10)