Grails: дубликаты и проверка уникальных ограничений - PullRequest
Новая
       11

Grails: дубликаты и проверка уникальных ограничений

0 голосов
/ 24 мая 2010

ОК, здесь урезанная версия того, что у меня в приложении

Домен исполнителя: 

class Artist {

    String name
    Date lastMined
    def artistService

    static transients = ['artistService']
    static hasMany = [events: Event]

    static constraints = {
        name(unique: true)
        lastMined(nullable: true)
    }

    def mine() {
        artistService.mine(this)
    }
}

Домен событий: 

class Event {

    String name
    String details
    String country
    String town
    String place
    String url
    String date

    static belongsTo = [Artist]
    static hasMany = [artists: Artist]

    static constraints = {
        name(unique: true)
        url(unique: true)
    }
}

ArtistService: 

class ArtistService {

    def results = [
        [
            name:"name",
            details:"details",
            country:"country",
            town:"town",
            place:"place",
            url:"url",
            date:"date"
        ]
    ]

    def mine(Artist artist) {
        results << results[0] // now we have a duplicate
        results.each {
            def event = new Event(it)
            if (event.validate()) {
                if (artist.events.find{ it.name == event.name }) {
                    log.info "grrr! valid duplicate name: ${event.name}"
                }
                artist.addToEvents(event)
            }
        }

        artist.lastMined = new Date()
        if (artist.events) {
            artist.save(flush: true)
        }
    }
}

В теории event.validate () должен возвращать false, и событие не будет добавлено к исполнителю, но это не .., что приводит к исключению БД на artist.save ()

Хотя я заметил, что если повторяющееся событие сохраняется, сначала все работает как задумано. Это ошибка или особенность? : P

Ответы [ 2 ]

2 голосов
/ 24 мая 2010

Вы должны заменить artist.addToEvents(event) на artist.addToEvents(event).save(), и это будет работать. Пока вы не вызывали метод save (), проверка не будет учитывать новое созданное событие

2 голосов
/ 24 мая 2010

Какая версия Grails? Я только что проверил этот код в консоли Grails 1.3.1: 

new Book(title: "Misery", author: "Stephen King").save()
new Book(title: "The Shining", author: "Stephen King").save()
new Book(title: "Colossus", author: "Niall Ferguson").save(flush: true)

def b = new Book(title: "Colossus", author: "Stephen King")
assert !b.validate()
println b.errors

Утверждение прошло и последняя строка сгенерировала вывод вроде: 

org.springframework.validation.BeanPropertyBindingResult: 1 errors
Field error in object 'Book' on field 'title': rejected value [Colossus]; codes [Book.title.unique.error.Book.title,...

Возможно, это была ошибка, которая сейчас исправлена?

...