Получение максимального значения float в SQL программно

Question

Существует ли метод для программного (в T-SQL) получения максимального (и минимального) значения типа данных?Что бы он действовал как float.MaxValue в C #.

Я хотел бы использовать его в некотором выборе, когда параметр не равен фактическим значениям в базе данных, поэтому я бы использовал что-токак

declare @min float
declare @max float
--fill @min and @max, can be null if undefined
select * from foo 
  where bar between isnull(@min,0 ) and isnull(@max,max(float)/*magic*/)

Answer 1

Несмотря на то, что нет никакого встроенного способа получить минимальное или максимальное значения, есть решение, которое кто-то собрал :

 CREATE TABLE datatype_extrema 
  (min_bit bit NOT NULL DEFAULT (0) CHECK (min_Bit=0) 
  ,max_bit           AS CAST(0x1 AS bit) 
  ,min_tinyint       AS CAST(0x00 AS tinyint) 
  ,max_tinyint       AS CAST(0xFF AS tinyint) 
  ,min_smallint      AS CAST(0x8000 AS smallint) 
  ,max_smallint      AS CAST(0x7FFF AS smallint) 
  ,min_int           AS CAST(0x80000000 AS int) 
  ,max_int           AS CAST(0x7FFFFFFF AS int) 
  ,min_bigint        AS CAST(0x8000000000000000 AS bigint) 
  ,max_bigint        AS CAST(0x7FFFFFFFFFFFFFFF AS bigint) 
  ,min_smalldatetime AS CAST('19000101 00:00' AS smalldatetime) 
  ,max_smalldatetime AS CAST('20790606 23:59' AS smalldatetime) 
  ,min_datetime      AS CAST('17530101 00:00:00.000' AS datetime) 
  ,max_datetime      AS CAST('99991231 23:59:59.997' AS datetime) 
  ) 
  INSERT INTO datatype_extrema DEFAULT VALUES 
  GO 
  CREATE TRIGGER nochange_datatype_extrema 
  ON datatype_extrema INSTEAD OF INSERT, UPDATE, DELETE 
  AS BEGIN 
    RAISERROR ('No changes allowed for table datatype_extrema.', 16, 1) 
    ROLLBACK TRANSACTION 
  END 
  GO 

После этого вы можете скопировать максимальное значение в локальную переменную или (при использовании запросов) перекрестное соединение с этой таблицей.

  Declare @max_int int 
  Set @max_int=(SELECT max_int FROM datatype_extrema) 
  IF COALESCE(@FirstInt, @max_int) < COALESCE(@SecondInt, 0) 

Answer 2

Вот значения по умолчанию для числа с плавающей запятой и реального типа (которого нет в принятом ответе):

select
    CAST('-1.79E+308' AS float) as MinFloat,
    CAST('1.79E+308' AS float) as MaxFloat,
    CAST('-3.40E+38' AS real) as MinReal,
    CAST('3.40E+38' AS real) as MaxReal

К сожалению, невозможно преобразовать их из varbinary, но varchar работает без проблем.

Answer 3

Для float и real значения min и max можно вычислить с помощью функции POWER:

SELECT
    max_float = (1 + (POWER(2e0, 52) - 1) / POWER(2e0, 52)) * POWER(2e0, 1023)
    , min_float = -(1 + (POWER(2e0, 52) - 1) / POWER(2e0, 52)) * POWER(2e0, 1023)
    , max_real = CAST((1 + (POWER(2e0,23)-1)/POWER(2e0,23)) * POWER(2e0,127) AS real)
    , min_real = CAST(-(1 + (POWER(2e0,23)-1)/POWER(2e0,23)) * POWER(2e0,127) AS real)

десятичные значения:

SELECT
    max_float = 1.7976931348623158E+308
    , min_float = -1.7976931348623158E+308
    , max_real = 3.4028234E+38
    , min_real = -3.4028234E+38

Answer 4

1.79769313486231580799909999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999

Это максимальное число float значение

Вот как это можно получить:

DECLARE @decimal_length int = 0
DECLARE @decimal_value varchar(max) = '1.79'
DECLARE @decimal_value_buffer varchar(max) = @decimal_value
DECLARE @new_int varchar(10) = '9'
DECLARE @dummy float
WHILE @decimal_length < 308
BEGIN

    SET @decimal_value = @decimal_value + @new_int

    BEGIN TRY
        SET @dummy =  CAST(@decimal_value + 'E+308' AS float)
        SET @decimal_length = @decimal_length + 1
        SET @decimal_value_buffer = @decimal_value
        SET @new_int = '9'
    END TRY
    BEGIN CATCH
        SET @decimal_value = @decimal_value_buffer
        SET @new_int = @new_int - 1
    END CATCH
END

PRINT @decimal_value