преобразование & # xD; в <br/> с использованием XSL 1.0 - PullRequest
Новая
       20

преобразование & # xD; в <br/> с использованием XSL 1.0

1 голос
/ 23 июня 2010

Учитывая XML из: 

<data>
<field>Value 1&#xD;Value 2&#xD;Value 3&#xD;</field>
</data>

Я хотел бы иметь возможность создать HTML-код для отображения значений и преобразовать &#xD; в <br/>

<html>
<head/>
<body>
<div>Field Values</div>
<div>Value 1<br/>Value 2<br/>Value 3<br/></div>
</body>
</html>

Однако я не могу придумать, как это сделать, используя версию XSL 1.0?

Я пытался 

<xsl:value-of select="field" disable-output-escaping="yes"/>

Однако весь текст отображается в одной строке.

Есть идеи / предложения?

Спасибо

Dave

Ответы [ 2 ]

2 голосов
/ 23 июня 2010

Вы можете использовать рекурсивный шаблон, сделайте замену: 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">
      <data>
        <xsl:call-template name="replaceCharsInString">
          <xsl:with-param name="stringIn" select="data/field" />
        </xsl:call-template>
      </data>
    </xsl:template>

  <xsl:template name="replaceCharsInString">
    <xsl:param name="stringIn"/>
    <xsl:choose>
      <xsl:when test="contains($stringIn,'&#xD;')">
        <xsl:value-of select="substring-before($stringIn,'&#xD;')"/>
        <br />
        <xsl:call-template name="replaceCharsInString">
          <xsl:with-param name="stringIn" 
                          select="substring-after($stringIn,'&#xD;')"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$stringIn"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>
1 голос
/ 23 июня 2010

Вот как можно заменить &#xD; на <br/>: 

<xsl:template match="data">
  <xsl:call-template name="add-br">
    <xsl:with-param name="text" select="field" />
  </xsl:call-template>
</xsl:template>

<xsl:template name="add-br">
  <xsl:param name="text" select="."/>
  <xsl:choose>
    <xsl:when test="contains($text, '&#xD;')">
      <xsl:value-of select="substring-before($text, '&#xD;')"/>
      <br/>
      <xsl:call-template name="add-br">
        <xsl:with-param name="text" select="substring-after($text,'&#xD;')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
  <xsl:value-of select="$text"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>
...