Запустить новый процесс как другой пользователь в vb.net

Question

В настоящее время я использую доморощенный метод для запуска процесса от имени другого пользователя в Vista, и я не могу избавиться от ощущения, что оно взломано и не идеально (в дополнение к тому факту, что оно вытесняет UAC , сбой моего приложения с исключением безопасности и вынудить меня полностью отключить UAC). Мой процесс состоит из двух проектов (так два файла EXE) - "интерфейс" и "заглушка запуска" - и вот процесс:

1. У пользователя есть ярлык, который запускает «Interface.exe notepad.exe»
2. Interface.exe имеет форму, которая запрашивает учетные данные, которые они хотели бы использовать
3. Interace.exe использует ProcessStartInfo для создания экземпляра LaunchStub.exe (LS) в качестве нового пользователя
4. LS использует ProcessStartInfo (с ShellExecute, установленной в значение true) для запуска запрошенного файла, и поскольку он уже запущен как запрошенный пользователь, таков и новый процесс.

Причина, по которой у меня есть двухэтапный процесс, заключается в том, что я хочу, чтобы пользователи могли щелкнуть правой кнопкой мыши любой файл, для которого ОС имеет действие по умолчанию (.EXE, .SQL, .MSC и т. Д.), И запустить его, и ProcessStartInfo поддерживает это только с включенным «UseShellExecute», но этот переключатель не позволяет мне использовать новые учетные данные, поэтому я могу использовать только одно за раз.

Это вызывает несколько проблем - во-первых, пользователь должен уже существовать на компьютере, что означает, что он должен был войти в систему ранее. Если для этого пользователя нет локального профиля, запрошенное приложение иногда запускается, но я получаю исключения из реестра и профиля, потому что приложение ожидает, что вещи еще не существуют (например, куст HKCU в реестре, чего не делает пользователь). есть, потому что они никогда не вошли в систему).

Я знаю, что смогу просто "повысить" права моего приложения до пользователя, которого они запрашивают, запустить мой новый процесс, а затем отменить повышение прав, но я не могу найти хороший пример кода для это, и я не уверен, что это позволило бы работать как совершенно другой пользователь. Это все имеет смысл? Я просто не могу не чувствовать, что есть лучший способ сделать это.

---

ОБНОВЛЕНИЕ: Я только что попробовал некоторый код олицетворения Я нашел в Интернете, но безрезультатно. При использовании вместе с ProcessStartInfo кажется, что он по-прежнему запускает процессы с использованием моего текущего имени входа, а не того, которое я предоставил, хотя я активировал олицетворение с использованием предоставленных учетных данных.

Answer 1

Скорее всего, вам нужно создать собственную функцию "shell" с помощью Win32 API.

Используя API CreateProcessWithLogonW, вы можете создавать новые процессы под разными учетными данными и, при желании, загружать информацию профиля пользователя.

В приведенном ниже фрагменте кода, если вы замените

• имя пользователя - с вашим именем пользователя
• домен - с вашим доменом или "vbNullString"
• пароль - с вашим паролем
• параметр 4 - заменить 0 на 'LOGON WITH PROFILE', чтобы загрузить указанный профиль пользователя.

Дополнительную информацию см. В документации по API CreateProcessWithLogonW . Пройдя по этому маршруту, вы получаете полный контроль и полную ответственность за запуск приложения.

Опять же, это всего лишь пример, и вам, возможно, придется немного поиграть с ним, чтобы заставить его делать то, что вы хотите.

Imports System.Runtime.InteropServices

Public Module modShell

    <StructLayout(LayoutKind.Sequential)> _
    Public Structure STARTUPINFO
        Public cb As Integer
        Public lpReserved As String
        Public lpDesktop As String
        Public lpTitle As String
        Public dwX As Integer
        Public dwY As Integer
        Public dwXSize As Integer
        Public dwYSize As Integer
        Public dwXCountChars As Integer
        Public dwYCountChars As Integer
        Public dwFillAttribute As Integer
        Public dwFlags As Integer
        Public wShowWindow As Short
        Public cbReserved2 As Short
        Public lpReserved2 As Integer
        Public hStdInput As Integer
        Public hStdOutput As Integer
        Public hStdError As Integer
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Public Structure PROCESS_INFORMATION
        Public hProcess As IntPtr
        Public hThread As IntPtr
        Public dwProcessId As Integer
        Public dwThreadId As Integer
    End Structure

    Public Declare Unicode Function CreateProcessWithLogonW Lib "Advapi32" (ByVal lpUsername As String, ByVal lpDomain As String, ByVal lpPassword As String, ByVal dwLogonFlags As Int32, ByVal lpApplicationName As String, ByVal lpCommandLine As String, ByVal dwCreationFlags As Int32, ByVal lpEnvironment As IntPtr, ByVal lpCurrentDirectory As String, ByRef si As STARTUPINFO, ByRef pi As PROCESS_INFORMATION) As Integer
    Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As IntPtr) As Integer

    Public Const LOGON_WITH_PROFILE As Int32 = &H1

    Public Const NORMAL_PRIORITY_CLASS As Int32 = &H20&

    Public Const STARTF_USESHOWWINDOW As Int32 = &H1
    Public Const SW_HIDE As Int16 = 0
    Public Const SW_SHOW As Int16 = 5

    Public Function Shell(ByVal strCmdLine As String, ByVal strCurrentDirectory As String) As Boolean

        Dim pi As PROCESS_INFORMATION
        Dim si As New STARTUPINFO

        si.cb = Marshal.SizeOf(si)
        si.dwFlags = STARTF_USESHOWWINDOW
        si.wShowWindow = SW_SHOW

        Dim result As Integer = CreateProcessWithLogonW("username", "domain", "password", 0, vbNullString, strCmdLine, NORMAL_PRIORITY_CLASS, IntPtr.Zero, strCurrentDirectory, si, pi)

        If result <> 0 Then
            Call CloseHandle(pi.hThread)
            Call CloseHandle(pi.hProcess)
        Else
            Return False
        End If

        Return True

    End Function

End Module

Answer 2

Вы можете попробовать запустить runas из вашего приложения. Некоторые примеры и варианты здесь .

Answer 3

Если вы хотите запустить приложение с учетными данными, отличными от текущего запущенного процесса, вы можете использовать класс .Net Process .

this.Process = new Process();

this.Process.StartInfo.Arguments = "Arguments";
this.Process.StartInfo.FileName = "C:\your.exe";
this.Process.StartInfo.UserName = "UserName";
string password = "some password";

this.Process.StartInfo.Password.Clear();
foreach (char c in password)
{
    this.Process.StartInfo.Password.AppendChar(c);
}


//allow the process to raise events
this.Process.EnableRaisingEvents = true;
this.Process.StartInfo.ErrorDialog = false;
//Method for handling the exit event
this.Process.Exited += new EventHandler(ApplicationProcess_Exited);

//Set the application directory as the current working directory
Environment.CurrentDirectory = System.IO.Directory.GetParent("C:\").ToString();

if (this.Process.Start())
{
    // Do something on start
}

Answer 4

Попробуйте этот модуль:

Module Impersonation

#Region "API Structures"
    <StructLayout(LayoutKind.Sequential)> _
      Public Structure PROCESS_INFORMATION
        Dim hProcess As System.IntPtr
        Dim hThread As System.IntPtr
        Dim dwProcessId As Integer
        Dim dwThreadId As Integer
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
     Public Structure STARTUPINFO
        Dim cb As Integer
        Dim lpReserved As System.IntPtr
        Dim lpDesktop As System.IntPtr
        Dim lpTitle As System.IntPtr
        Dim dwX As Integer
        Dim dwY As Integer
        Dim dwXSize As Integer
        Dim dwYSize As Integer
        Dim dwXCountChars As Integer
        Dim dwYCountChars As Integer
        Dim dwFillAttribute As Integer
        Dim dwFlags As Integer
        Dim wShowWindow As Short
        Dim cbReserved2 As Short
        Dim lpReserved2 As System.IntPtr
        Dim hStdInput As System.IntPtr
        Dim hStdOutput As System.IntPtr
        Dim hStdError As System.IntPtr
    End Structure
#End Region

#Region "API Constants"
    Private Const LOGON_NETCREDENTIALS_ONLY As Integer = &H2
    Private Const NORMAL_PRIORITY_CLASS As Integer = &H20
    Private Const CREATE_DEFAULT_ERROR_MODE As Integer = &H4000000
    Private Const CREATE_NEW_CONSOLE As Integer = &H10
    Private Const CREATE_NEW_PROCESS_GROUP As Integer = &H200
    Private Const LOGON_WITH_PROFILE As Integer = &H1
#End Region

#Region "API Functions"
    Private Declare Unicode Function CreateProcessWithLogon Lib "Advapi32" Alias "CreateProcessWithLogonW" _
        (ByVal lpUsername As String, _
         ByVal lpDomain As String, _
         ByVal lpPassword As String, _
         ByVal dwLogonFlags As Integer, _
         ByVal lpApplicationName As String, _
         ByVal lpCommandLine As String, _
         ByVal dwCreationFlags As Integer, _
         ByVal lpEnvironment As System.IntPtr, _
         ByVal lpCurrentDirectory As System.IntPtr, _
         ByRef lpStartupInfo As STARTUPINFO, _
         ByRef lpProcessInfo As PROCESS_INFORMATION) As Integer

    Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As System.IntPtr) As Integer

#End Region

    Public Sub RunProgram(ByVal UserName As String, ByVal Password As String, ByVal Domain As String, ByVal Application As String, ByVal CommandLine As String)

        Dim siStartup As STARTUPINFO
        Dim piProcess As PROCESS_INFORMATION
        Dim intReturn As Integer

        If CommandLine Is Nothing OrElse CommandLine = "" Then CommandLine = String.Empty

        siStartup.cb = Marshal.SizeOf(siStartup)
        siStartup.dwFlags = 0

        intReturn = CreateProcessWithLogon(UserName, Domain, Password, LOGON_WITH_PROFILE, Application, CommandLine, _
        NORMAL_PRIORITY_CLASS Or CREATE_DEFAULT_ERROR_MODE Or CREATE_NEW_CONSOLE Or CREATE_NEW_PROCESS_GROUP, _
        IntPtr.Zero, IntPtr.Zero, siStartup, piProcess)

        If intReturn = 0 Then
            Throw New System.ComponentModel.Win32Exception(Marshal.GetLastWin32Error())
        End If

        CloseHandle(piProcess.hProcess)
        CloseHandle(piProcess.hThread)

    End Sub

End Module

Используйте Runprogram (), чтобы запустить вашу Программу с пользователем / pw y like. Программа означает только .exe, параметры записываются в «командную строку»