Печать набора пар ключ-значение данных внутри элемента XML с использованием XSLT - PullRequest
Новая
       0

Печать набора пар ключ-значение данных внутри элемента XML с использованием XSLT

1 голос
/ 05 ноября 2010

Для данного XML-узла мне нужно получить пары ключ-значение.Например:

Для XML: 

<root>
    <detail1>
        <test1> Text1 </test1>
        <test2> Text2 </test2>
        <test3> Text3 </test3>
    </detail1>
    <detail2> description 1 </detail2>
    <detail3> description 2 </detail3>
</root>

Мне нужна следующая таблица (Игнорируется самый верхний элемент): 


detail1 | test1 : Text1 
        | test2 : Text2
        | test2 : Text3
        |
detail2 | description 1
        |
detail3 | description 2

Возможно ли это с XSLT?Если кто-нибудь может указать мне пример или ресурс, это было бы очень полезно.

Ответы [ 5 ]

2 голосов
/ 05 ноября 2010

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vBlanks" select="'                         '"/>

 <xsl:template match="/*/*">
  <xsl:value-of select="concat('&#xA;', name(), ' | ')"/>
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="/*/*/*">
  <xsl:value-of select="concat(name(), ' : ')"/>
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="/*/*/*[not(position()=1)]">
  <xsl:text>&#xA;</xsl:text>
  <xsl:value-of select="substring($vBlanks,1,string-length(name(..))+1)"/>
  <xsl:value-of select="concat('| ', name(), ' : ')"/>
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному XML-документу : 

<root>
    <detail1>
        <test1> Text1 </test1>
        <test2> Text2 </test2>
        <test3> Text3 </test3>
    </detail1>
    <detail2> description 1 </detail2>
    <detail3> description 2 </detail3>
</root>

создает искомое, правильный результат : 

detail1 | test1 :  Text1 
        | test2 :  Text2 
        | test3 :  Text3 
detail2 |  description 1 
detail3 |  description 2
1 голос
/ 05 ноября 2010

Эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/*">
        <table border="1px">
            <xsl:apply-templates/>
        </table>
    </xsl:template>
    <xsl:template match="/*/*">
        <tr>
            <td>
                <xsl:value-of select="name()"/>
            </td>
            <td>
                <xsl:apply-templates/>
            </td>
        </tr>
    </xsl:template>
    <xsl:template match="/*/*/*">
        <xsl:value-of select="concat(name(),' : ')"/>
        <xsl:apply-templates/>
        <xsl:if test="following-sibling::*">
            <br/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Выход: 

<table border="1px">
    <tr>
        <td>detail1</td>
        <td>test1 :  Text1 
            <br />test2 :  Text2 
            <br />test3 :  Text3 
        </td>
    </tr>
    <tr>
        <td>detail2</td>
        <td> description 1 </td>
    </tr>
    <tr>
        <td>detail3</td>
        <td> description 2 </td>
    </tr>
</table>
1 голос
/ 05 ноября 2010

Да. Вам нужен тег for-each, который позволяет циклически повторять результат выражения XPath.

См. http://www.w3schools.com/xsl/xsl_for_each.asp для объяснения и варианта использования.

1 голос
/ 05 ноября 2010

Мне нравится использовать xsl: apply-templates лучше, чем использовать xsl: for-each.

Редактировать: измененное предложение о совпадении с *[text()] на *[count(text()) = 1]

Если вы примените это преобразование 

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="/">
    <html>
      <table>
        <xsl:apply-templates select="root/*"/>
      </table>
    </html>
  </xsl:template>

  <xsl:template match="*[count(text()) = 1]">
    <tr>
      <td>
        <xsl:value-of select="name()"/>
      </td>
      <td>
        <xsl:value-of select="."/>
      </td>
    </tr>
  </xsl:template>

  <xsl:template match="*">
    <xsl:apply-templates select="*" mode="keyvalue"/>
  </xsl:template>

  <xsl:template match="*" mode="keyvalue">
    <tr>
      <xsl:choose>
        <xsl:when test="position() = 1">
          <td>
            <xsl:value-of select="name(..)"/>
          </td>
          <td>
            <xsl:call-template name="formatkeyvalue"/>
          </td>
        </xsl:when>
        <xsl:otherwise>
          <td></td>
          <td>
            <xsl:call-template name="formatkeyvalue"/>
          </td>
        </xsl:otherwise>
      </xsl:choose>
    </tr>
  </xsl:template>

  <xsl:template name="formatkeyvalue">
    <xsl:value-of select="concat(name(), ' : ', text())"/>
  </xsl:template>

</xsl:stylesheet>

к вашему входу, вы получите 

<html>
  <table>
    <tr>
      <td>detail1</td>
      <td>test1 :  Text1 </td>
    </tr>
    <tr>
      <td></td>
      <td>test2 :  Text2 </td>
    </tr>
    <tr>
      <td></td>
      <td>test3 :  Text3 </td>
    </tr>
    <tr>
      <td>detail2</td>
      <td> description 1 </td>
    </tr>
    <tr>
      <td>detail3</td>
      <td> description 2 </td>
    </tr>
  </table>
</html>
1 голос
/ 05 ноября 2010

Вы должны посмотреть на Печать имен и значений тегов XML в Java . Основная идея состоит в том, чтобы называть функции name () и text (), и создание формата должно быть относительно простым

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...