xslt пропустить уже "посещенные" узлы

Question

не уверен, что это возможно без необходимости проходить несколько проходов, но я все равно спрошу (мой XSL немного ржавый)

У меня есть XML-документ, который содержит следующие узлы:

<structures>
 <structure id="STRUCT_A">
   <field idref="STRUCT_B" name="b"/>
   <field idref="STRUCT_C" name="c"/>
   <field idref="FIELD_D" name="d"/>
 </structure>

 <structure id="STRUCT_B">
   <field idref="STRUCT_C" name="c"/>
   <field idref="FIELD_E" name="e"/>
 </structure>

 <structure id="STRUCT_C">
   <field idref="FIELD_E" name="e"/>
   <field idref="FIELD_F" name="f"/>
   <field idref="FIELD_G" name="g"/>
 </structure>
</structures>

(Реальный файл содержит множество структурных тегов с взаимозависимостями, ни один из которых не является круглым!)

Что я хочу сделать, это сгенерировать некоторый текст (в данном случае C ++ struct s), и очевидным требованием является порядок struct s, поэтому мой идеальный вывод будет

struct STRUCT_C
{
  FIELD_E e;
  FIELD_F f;
  FIELD_G g;
};

struct STRUCT_B
{
  STRUCT_C c;
  FIELD_E e;
};

struct STRUCT_A
{
  STRUCT_B b;
  STRUCT_C c;
  FIELD_D d;
};

Я знаю, что мог бы использовать предварительные объявления, и это означало бы, что порядок не имеет значения, однако проблема в том, что в структурах будет «обрабатываться» встроенный код, и им потребуется настоящее определение.

Пока я могу определить, есть ли у structure какие-либо зависимости со следующим битом xsl:

<xsl:for-each select="descendant::*/@idref">
  <xsl:variable name="name" select="."/>
  <xsl:apply-templates select="//structure[@id = $name]" mode="struct.dep"/> 
</xsl:for-each>

(это происходит внутри <xsl:template match="structure">)

Теперь, теоретически, я мог бы затем следовать этой «цепочке» зависимостей и генерировать сначала struct для каждой записи, затем ту, на которой я сейчас нахожусь, однако, как вы можете себе представить, это генерирует множество копий та же структура - это боль ..

Есть ли способ избежать копий? По сути, после того, как структура была посещена, и если мы посетим снова, чтобы не беспокоиться о выводе кода для нее ... Мне не нужен полный xslt, чтобы сделать это (если это не тривиально!), Но только любые идеи о подходах ...

Если нет, то теоретически я могу обернуть struct защитой #ifdef / #define / #endif, чтобы компилятор использовал только первое определение, однако это ДЕЙСТВИТЕЛЬНО ГРОМКО! (

(ПРИМЕЧАНИЯ: xslt 1.0, xsltproc в Linux: использование libxml 20623, libxslt 10115 и libexslt 812)

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vLeafs" select="/*/structure[not(field/@idref = /*/structure/@id)]"/>

 <xsl:template match="/*">
  <xsl:apply-templates select="$vLeafs[1]">
   <xsl:with-param name="pVisited" select="'|'"/>
  </xsl:apply-templates>

 </xsl:template>

 <xsl:template match="structure">
   <xsl:param name="pVisited"/>

struct <xsl:value-of select="@id"/>
{<xsl:text/>
  <xsl:apply-templates/>
};
  <xsl:variable name="vnewVisited"
       select="concat($pVisited, @id, '|')"/>
  <xsl:apply-templates select=
  "../structure[not(contains($vnewVisited, concat('|', @id, '|')))
              and
                not(field/@idref
                           [not(contains($vnewVisited, concat('|', ., '|')) )
                          and
                           . = ../../../structure/@id
                           ]
                   )
               ] [1]
  ">
   <xsl:with-param name="pVisited" select="$vnewVisited"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="field">
  <xsl:value-of select="concat('&#xA;   ', @idref, ' ', @name, ';')"/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<structures>
 <structure id="STRUCT_A">
   <field idref="STRUCT_B" name="b"/>
   <field idref="STRUCT_C" name="c"/>
   <field idref="FIELD_D" name="d"/>
 </structure>

 <structure id="STRUCT_B">
   <field idref="STRUCT_C" name="c"/>
   <field idref="FIELD_E" name="e"/>
 </structure>

 <structure id="STRUCT_C">
   <field idref="FIELD_E" name="e"/>
   <field idref="FIELD_F" name="f"/>
   <field idref="FIELD_G" name="g"/>
 </structure>
</structures>

дает желаемый, правильный результат :

struct STRUCT_C
{
   FIELD_E e;
   FIELD_F f;
   FIELD_G g;
};


struct STRUCT_B
{
   STRUCT_C c;
   FIELD_E e;
};


struct STRUCT_A
{
   STRUCT_B b;
   STRUCT_C c;
   FIELD_D d;
};

Объяснение : structure элементы обрабатываются строго по одному. В любое время мы обрабатываем первый элемент structure, чей id еще не зарегистрирован в параметре pVisited и у которого нет значения field/@idref, которого еще нет в параметре pVisited и который ссылается на существующий structure элемент.

Answer 2

Просто для удовольствия, другой подход (уровень за уровнем) и использование клавиш:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kStructById" match="structure" use="@id"/>
    <xsl:key name="kStructByIdref" match="structure" use="field/@idref"/>
    <xsl:template match="/">
        <xsl:param name="pParents" select="/.."/>
        <xsl:param name="pChilds"
                   select="structures/structure[not(key('kStructById',
                                                        field/@idref))]"/>
        <xsl:variable name="vParents" select="$pParents|$pChilds"/>
        <xsl:variable name="vChilds"
                      select="key('kStructByIdref',$pChilds/@id)
                                 [count(key('kStructById',
                                             field/@idref) |
                                        $vParents) =
                                  count($vParents)]"/>
        <xsl:apply-templates select="$pChilds"/>
        <xsl:apply-templates select="current()[$vChilds]">
            <xsl:with-param name="pParents" select="$vParents"/>
            <xsl:with-param name="pChilds" select="$vChilds"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="structure">
        <xsl:value-of select="concat('struct ',@id,'&#xA;{&#xA;')"/>
        <xsl:apply-templates/>
        <xsl:text>};&#xA;</xsl:text>
    </xsl:template>
    <xsl:template match="field">
        <xsl:value-of select="concat('&#x9;',@idref,' ',@name,';&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>

Выход:

struct STRUCT_C
{
    FIELD_E e;
    FIELD_F f;
    FIELD_G g;
};
struct STRUCT_B
{
    STRUCT_C c;
    FIELD_E e;
};
struct STRUCT_A
{
    STRUCT_B b;
    STRUCT_C c;
    FIELD_D d;
};

Answer 3

Ох, это сложнее, чем казалось на первый взгляд. +1 за хороший вопрос.

Я думаю, что лучший способ сделать это в XSLT 1.0 - передать накопительный параметр всякий раз, когда вы применяете шаблоны к структуре. Параметр (назовите его «$ посещения-структуры») - это список имен структур, которые вы уже обработали.

Обновление: наконец-то получил это. : -)

В шаблоне для обработки структуры проверьте, не указаны ли какие-либо другие структуры, от которых зависит эта структура, в $ посещения-структурах. Если нет, сгенерируйте код для этой структуры и выполните повторный поиск по шаблону, выбрав следующую не посещенную структуру, добавив имя текущей структуры к параметру $ посещения-структур. В противном случае, не генерируйте код для структуры, а используйте шаблон, выбирающий первую структуру зависимостей, передав параметр $ visit-структура без изменений.

Вот код ...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">
   <xsl:key name="structuresById" match="/*/structure" use="@id" />

   <xsl:template match="structures">
      <xsl:apply-templates select="structure[1]" >
         <!-- a space-delimited list of id's of structures already processed, with space
            at beginning and end. Could contain duplicates. -->
         <xsl:with-param name="visited-structures" select="' '"/>
      </xsl:apply-templates>
   </xsl:template>

   <xsl:template match="structure">
      <xsl:param name="visited-structures" select="' '" />  
      <xsl:variable name="dependencies" select="key('structuresById', field/@idref)
                     [not(contains($visited-structures, @id))]"/>
      <xsl:choose>
         <xsl:when test="$dependencies">
            <xsl:apply-templates select="$dependencies[1]">
               <xsl:with-param name="visited-structures" select="$visited-structures"/>
            </xsl:apply-templates>            
         </xsl:when>
         <xsl:otherwise>
            <!-- Now generate code for this structure ... ... -->
struct <xsl:value-of select="@id"/>
{
<xsl:apply-templates select="field"/>};
            <xsl:variable name="new-visited" select="concat(' ', @id, $visited-structures)"/>
            <xsl:apply-templates select="/*/structure[not(contains($new-visited, @id))][1]" >
               <xsl:with-param name="visited-structures" select="$new-visited"/>
            </xsl:apply-templates>
         </xsl:otherwise>
      </xsl:choose>      
   </xsl:template>

   <xsl:template match="field">
      <xsl:value-of select="concat('  ', @idref, ' ', @name, ';&#xa;')"/>      
   </xsl:template>

</xsl:stylesheet>

И вывод:

<?xml version="1.0" encoding="utf-8"?>

struct STRUCT_C
{
  FIELD_E e;
  FIELD_F f;
  FIELD_G g;
};


struct STRUCT_B
{
  STRUCT_C c;
  FIELD_E e;
};


struct STRUCT_A
{
  STRUCT_B b;
  STRUCT_C c;
  FIELD_D d;
};