Используйте функцию замены xslt, чтобы заменить слово элементом - PullRequest
Новая
       8

Используйте функцию замены xslt, чтобы заменить слово элементом

3 голосов
/ 10 декабря 2010

Я хочу использовать функцию замены XSLT для замены слов в тексте на 

<strong>word</strong>.

. Я написал следующий шаблон: 

<xsl:template name="make-bold">
  <xsl:param name="text"/>
  <xsl:param name="word"/>
  <xsl:variable name="replacement">
     <strong><xsl:value-of select="$word"/></strong>
  </xsl:variable>
  <xsl:value-of select="replace($text, $word,  $replacement )" />
</xsl:template>

К сожалению, и не отображаются, хотя все остальное работает.

Кто-нибудь может мне помочь?

Best, Suidu

Ответы [ 2 ]

3 голосов
/ 10 декабря 2010

Хорошо, функция замены http://www.w3.org/TR/xpath-functions/#func-replace принимает строку и возвращает строку. Вы, кажется, хотите создать узел элемента, а не простую строку. В этом случае может помочь анализ-строка http://www.w3.org/TR/xslt20/#analyze-string вместо замены.

Вот пример таблицы стилей XSLT 2.0: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">

  <xsl:output method="html" indent="no"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@*, node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="p">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="text()" mode="wrap">
        <xsl:with-param name="words" as="xs:string+" select="('foo', 'bar')"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="text()" mode="wrap">
    <xsl:param name="words" as="xs:string+"/>
    <xsl:param name="wrapper-name" as="xs:string" select="'strong'"/>
    <xsl:analyze-string select="." regex="{string-join($words, '|')}">
      <xsl:matching-substring>
        <xsl:element name="{$wrapper-name}">
          <xsl:value-of select="."/>
        </xsl:element>
      </xsl:matching-substring>
      <xsl:non-matching-substring>
        <xsl:value-of select="."/>
      </xsl:non-matching-substring>
    </xsl:analyze-string>
  </xsl:template>

</xsl:stylesheet>

Когда вы запускаете его с процессором XSLT 2.0, таким как Saxon 9, со следующим примером ввода 

<html>
  <body>
    <p>This is an example with foo and bar words.</p>
  </body>
</html>

вывод выглядит следующим образом: 

<html>
  <body>
    <p>This is an example with <strong>foo</strong> and <strong>bar</strong> words.</p>
  </body>
</html>
0 голосов
/ 10 декабря 2010

хмм, потому что здесь это строковое значение, которое заменяется, вы можете попробовать использовать набор узлов?

я не могу проверить, так как я не использую xslt 2.0, но вы можете попробовать рекурсивный шаблон, например 

<xsl:template match="yourtextelement">
   <xsl:call-template name="MaketextStrong">
</xsl:template>

<xsl:template name="MaketextStrong">
   <xsl:param name="text" select="."/>
   <xsl:choose>
   <xsl:when test="contains($text, 'texttomakestrong')">
      <xsl:value-of select="substring-before($text, 'texttomakestrong')"/>
      <strong>texttomakestrong</strong>
      <xsl:call-template name="break">
          <xsl:with-param name="text" select="substring-after($text,
'texttomakestrong')"/>
      </xsl:call-template>
   </xsl:when>
   <xsl:otherwise>
 <xsl:value-of select="$text"/>
   </xsl:otherwise>
   </xsl:choose>
</xsl:template>
...