Как скопировать набор узлов в результирующий атрибут, используя XSLT без пробелов и кодированных тегов?

Question

Учитывая этот XML ...

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <item>
        <this>
<that>one</that>
        </this>
    </item>
    <item>
        <this>
<that>two</that>
        </this>
    </item>
    <item>
        <this>
<that>three</that>
        </this>
    </item>
</root>

Я хочу сделать копии предметов в новом формате, который выглядит как ...

<new>
  <parm x="&gt;that&lt;one&gt;/that&lt;"/>
  <parm x="&gt;that&lt;two&gt;/that&lt;"/>
  <parm x="&gt;that&lt;three&gt;/that&lt;"/>
</new>

Таблица стилей ...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="feedKey"/>

    <xsl:template match="/">
        <new>
            <xsl:apply-templates select="//item"/>
        </new>
    </xsl:template>

    <xsl:template match="item">
        <xsl:element name="param">
            <xsl:attribute name="x"><xsl:copy-of select="node()"/></xsl:attribute>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

... производит ...

<?xml version="1.0" encoding="UTF-8"?>
<new>
   <param x="&#xA;        &#xA;one&#xA;        &#xA;    "/>
   <param x="&#xA;        &#xA;two&#xA;        &#xA;    "/>
   <param x="&#xA;        &#xA;three&#xA;        &#xA;    "/>
</new>

Простое изменение листа для удаления атрибута ...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="feedKey"/>

    <xsl:template match="/">
        <new>
            <xsl:apply-templates select="//item"/>
        </new>
    </xsl:template>

    <xsl:template match="item">
        <xsl:element name="param">
            <xsl:copy-of select="node()"/>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

... производит ...

<?xml version="1.0" encoding="UTF-8"?>
<new>
   <param>
        <this>
         <that>one</that>
        </this>
    </param>
   <param>
        <this>
         <that>two</that>
        </this>
    </param>
   <param>
        <this>
         <that>three</that>
        </this>
    </param>
</new>

Как я могу преобразовать "this" в атрибут "x" с убранным пробелом и кодированными тегами?

Answer 1

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <new>
    <xsl:apply-templates select="*/*/this/*"/>
  </new>
 </xsl:template>

 <xsl:template match="*">
  <xsl:variable name="vStr">
    <xsl:text>&lt;</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>&gt;</xsl:text>

    <xsl:apply-templates/>

    <xsl:text>&lt;/</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>&gt;</xsl:text>
  </xsl:variable>

  <parm x="{$vStr}"/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<root>
    <item>
        <this>
            <that>one</that>
        </this>
    </item>
    <item>
        <this>
            <that>two</that>
        </this>
    </item>
    <item>
        <this>
            <that>three</that>
        </this>
    </item>
</root>

дает желаемоерезультат :

<new>
    <parm x="&lt;that&gt;one&lt;/that&gt;"/>
    <parm x="&lt;that&gt;two&lt;/that&gt;"/>
    <parm x="&lt;that&gt;three&lt;/that&gt;"/>
</new>

Answer 2

Насколько мне известно, и если я правильно понимаю ваш вопрос;в XSLT нет способа сделать это.Мое предположение состоит в том, что W3C рассматривает сохранение экранированного XML как антишаблон.Мой подход состоял в том, чтобы определить именованный шаблон:

<xsl:template name='recursive_escape'>
<xsl:text>;&lt;</xsl:text>
<xsl:value-of select='local-name()'/>
<xsl:for-each select='child::attribute()'>
<xsl:value-of select='local-name()'/>
<xsl:text>='</xsl:text><xsl:value-of select='.'/><xsl:text>'</xsl:text>
</xsl:for-each>
<xsl:text>/;&gt;</xsl:text>....

И так далее.Я надеюсь, что вы можете расшифровать то, что я пытаюсь сделать здесь: создать вручную открывающий тег с именем узла контекста и именем и значением каждого атрибута, затем выполнить итерацию по каждому дочернему узлу узла контекста и вызвать тот же шаблонснова;и так далее.У меня нет исходной реализации, поэтому, без сомнения, в моем примере есть несколько ошибок;это просто руководство.

Если кто-нибудь знает, как лучше, я бы хотел это услышать;это может быть в XSLT 2.0, который еще не оформлен, IIRC.Для надежности и поддержки MSXML это должен быть XSLT 1.0.