Есть ли способ нанести график смены дня на часовую шкалу на оси x? - PullRequest
Новая
       15

Есть ли способ нанести график смены дня на часовую шкалу на оси x?

2 голосов
/ 18 ноября 2010

Я использую gnuplot для построения зависящих от времени данных.

Сэмплы берутся каждые 5 минут или около того, и у меня есть 200 сэмплов.

Я строю их с отформатированной осью Xна 

set format x "%H:%M"

В идеале, я хотел бы напечатать дату всякий раз, когда ось X пересекает полночь ... но только , когда она пересекает полночь.Что-то вроде: 

22:00   22:30   23:00   23:30   00:00   00:30   01:00
                              2010-11-17

Кто-нибудь из гну gnuplot знает способ сделать это?

1 Ответ

2 голосов
/ 19 ноября 2010

Хороший вопрос.

Следующее основано на t16web.lanl.gov / Kawano / gnuplot / plot4-e.html # 5.12.

В основном вам необходимо построить данные дважды, по одному для каждой оси. Во второй раз, когда я строю данные, я перемещаю фактический график вне диапазона (вычитая 1000), так что рисуется только один график. Следующий сценарий оболочки генерирует данные и строит их, как показано на графике ниже.

Надеюсь, это то, что вы хотите. 

#!/bin/bash

echo "2010-11-17 13:30:01,1
2010-11-17 13:30:12,3.1
2010-11-18 13:30:23,2.1
2010-11-19 13:30:34,4" > two_axis.dat

gnuplot<<EOF
## Plot a second axis with the day rather than the time
## Based on example from http://t16web.lanl.gov/Kawano/gnuplot/plot4-e.html#5.12.

##  make a png file
set term png small
set output "two_axis.png"
## reduce the size of the main plot to allow for second axis
set size 1.0,0.8
set bmargin 0
set lmargin 3  # set space given to axis
## The data for the second plot will be set to be out of range,
##     Need to explicitly set range here.
set yrange [0:5] 

set multiplot

## Main plot, raised slightly
set origin 0,0.2
set datafile separator "," 
set xdata time
set timefmt "%Y-%m-%d %H:%M:%S" 
set format x "%H:%M" 

## Need to set xrange so that the axes of the two plots match exactly
set xrange["2010-11-17 12:00:00":"2010-11-19 14:00:00"]

## The main plot!
plot "./two_axis.dat" using 1:2 with lines

## Now want to draw second axis with just the days
set origin 0,0.1
## Dont want any ytics or minor xtics or drawn axes
set noytics
unset mxtics
unset border
## Don't want axis mirrored, want tick scales to zero so that it vanishes,
##    And some format for the days of the week axis
set xtics nomirror scale 0 format "%Y-%m-%d"

##  Specify the tics interval in seconds 1 day = 86400 seconds
set xtics "2010-11-01 00:00:00", 86400,   "2010-12-01 00:00:00"

## Replot the graph but this time with the data shifted out of the way,
##  we don't want to replot the data (difficult to align with previous plot) - 
##  we just want the axis
plot "./two_axis.dat" using 1:(\$2-1000) with lines notitle

## clean up
unset multiplot
set output
set term pop
EOF

alt text

Всего наилучшего,

Tom

...