.bat Найти и заменить текст

Question

У меня есть некоторые файлы, которые содержат некоторые, если не все, следующие:

Программа RxBIN RXPCN RxGroup MemberID

не все файлы будут иметь все эти заголовки, но те, которые янужно будет заменить, чтобы он выглядел так:

@ Program @RxBIN @RXPCN @RxGroup @ MemberID

Заранее спасибо, Джо

Answer 1

Я все еще был бы склонен использовать инструмент, созданный для этой цели: Batch Replacer , кажется, идеально подходит для счета.

Но если вы не уверены в этом... что-то, использующее старый repl.bat с парсером multi arg ... это становится чем-то вроде монстра, который использует команду DEBUG , но вот последний шедевр:

Исходный код: mmrepl.bat

@ECHO OFF
setLocal EnableDelayedExpansion

::: mmrepl - Replaces one or more strings with others, in file(s)
:::
::: syntax: mmrepl.bat $file $find $replace [$find $replace] ...
:::            $file    [in] - file to be parsed
:::            $find    [in] - string to find
:::            $replace [in] - string to replace with
:::
:::         * $find & $replace should be supplied in pairs, n multiples allowed
:::         * $file can be a single file (eg.txt) or a file filter (*.txt)
:::           you can supply any command that works with 'dir /b $file'
:::           so paths and drives are also valid.
:::         * $find,$replace strings can be single words, or strings enclosed
:::            in quotes (which will be stripped)
if "%~1"=="" findstr "^:::" "%~f0"&GOTO:EOF
if not exist %1 echo No files matching %1 found&GOTO:EOF

::Creates the following log file:
set log=%0.log
::Temporarily creates the following files but cleans up
set replscr=TEMPDEBUG.SCR
set cmplsrc=TEMPEDLN.SCR

echo To see the work of %0.bat view the log file %log%
echo Multi-Multi Replacement (%0.bat)>%log%
echo.>>%log%
set "files=%1"
shift
set mmreplcmd=
:: Pair up find/replaces
:strippairs
set p1=%1
set p1=!p1:"=!
set p2=%2
set p2=!p2:"=!
SET mmreplcmd=%mmreplcmd%'1R%p1%' 1A '%p2%' 0D 0A 
echo Replacing "%p1%" with "%p2%" >> %log%
shift
shift
if "%~1" neq "" goto:strippairs

::Build script
echo N%cmplsrc% > %replscr%
echo E CS:100 %mmreplcmd%'E' 0D 0A>> %replscr%
echo RCX >> %replscr%
echo 40 >> %replscr%
echo W >> %replscr%
echo Q >> %replscr%
DEBUG < %replscr% > NUL
::Execute on files
for /f %%a IN ('dir /b %files%') do (
  echo.>>%log%
  echo *** File: %%a >> %log%
  EDLIN %%a < %cmplsrc% >> %log%
)
DEL %replscr%
DEL %cmplsrc%

ПРИМЕЧАНИЕ : я должен был удалить «содержится» в поиске repl.bat потому что вы добавляете амперсанд к каждому заголовку, чтобы он всегда содержал ... мое тестирование показывает, что это работает нормально, но YMMV (тест).

Answer 2

Это можно сделать тривиально с помощью sed ( s tream ed itor), который доступен для Windows в нескольких местах .

Это можно сделать с помощью чего-то вроде

sed -e "s/\(Program\|RxBIN\|RXPCN\|RxGroup\|MemberID\)/@\1/g" myfile.txt > newfile.txt

Это регулярное выражение, которое в основном говорит «заменить слово« Программа »или« RxBIN »или« RXPCN »или«RxGroup 'или' MemberID ', знак at и любое слово, которое было найдено. "

Существует множество замечательных команд Unix, перенесенных в Windows, которые могут быть чрезвычайно полезны.