замените значение переменной и сохраните ее в новой переменной

Question

У меня есть код ниже, чтобы заменить значение переменной и сохранить ее в новой переменной и оставить исходную переменную нетронутой.

#!/usr/bin/perl
$hdisk="hdisk361";
($newdisk) = ($hdisk =~ s/(hdisk\D*)(\d+)/(($1 eq "hdiskpower"?"prw":"dsk").$2)/ei);
print "hdisk: $hdisk"."\n";
print "newdisk: $newdisk"."\n";

Это дает такой вывод:

hdisk: dsk361
newdisk: 1

Я хочувывод такой:

hdisk: hdisk361
newdisk: dsk361

Пожалуйста, помогите мне исправить этот код?

Answer 1

Или немного короче:

#!/usr/bin/perl
$hdisk="hdisk361";
($newdisk = $hdisk) =~ s/(hdisk\D*)(\d+)/(($1 eq "hdiskpower"?"prw":"dsk").$2)/ei;

В противном случае, как вы видели, вы получите 1, что означает успешную операцию.В предоставленном вами коде вы взяли возвращаемое значение вместо результата.

Но не забудьте использовать use strict и use warnings;)

Answer 2

Подстановка s/// работает по побочному эффекту.Его возвращаемое значение вряд ли когда-либо, что вы хотите.Вы особенно не хотите использовать s здесь, когда вы, кажется, не хотите, чтобы $hdisk изменился.

Захватывайте куски $hdisk с m вместо s.

use strict;
use warnings;
my $hdisk="hdisk361"; 
my ($word, $number) = $hdisk =~ m/(hdisk\D*)(\d+)/i;
my $newdisk = ($word eq "hdiskpower"?"prw":"dsk").$number; 
print "hdisk: $hdisk"."\n";
print "newdisk: $newdisk"."\n"; 

Answer 3

Используйте

$hdisk = "hdisk361"
$newdisk = $hdisk;
$newdisk =~ s/(hdisk\D*)(\d+)/(($1 eq "hdiskpower"?"prw":"dsk").$2/

Answer 4

Этот ответ немного излишний, но в любом случае, если вы используете довольно современную версию Perl (5.13+), вы можете получить оригинальный код, просто добавив флаг r:

use 5.013;
($newdisk) = ($hdisk =~ s/(hdisk\D*)(\d+)/(($1 eq "hdiskpower"?"prw":"dsk").$2)/rei);

Вы даже можете отпустить парены:

use 5.013;
my $newdisk = $hdisk =~ s/(hdisk\D*)(\d+)/(($1 eq "hdiskpower"?"prw":"dsk").$2)/rei;

Подробнее о флаге /r можно прочитать на Используйте флаг замены / r для работы с копией .