Результат обтекания XQuery в вычисляемом узле

Question

Я пытаюсь сделать простую нумерацию страниц в XQuery.Я хотел бы, чтобы мой корневой элемент возвращаемого XML имел (в качестве атрибутов) различные свойства о разбиении на страницы (текущая страница и т. Д.).

Однако я не могу найти способ добавить эти динамические атрибуты в мойкорневой элемент.Я пытался поиграть с функциями имени элемента {expr} и имени атрибута {expr}, но не могу заставить их работать.

<result>{

let $results :=
for $item in doc('mydoc')/root/item
return $item

let $requested-page-nbr := 2
let $items-per-page := 10
let $count := count($results)

let $last-page-nbr := fn:ceiling($count div $items-per-page)
let $actual-page-nbr := if ($requested-page-nbr gt $last-page-nbr) then $last-page-nbr else $requested-page-nbr
let $start-item := $items-per-page * $actual-page-nbr - ( $items-per-page - 1 )
let $natural-end-item := $actual-page-nbr * $items-per-page
let $actual-end-item := if ($count ge $natural-end-item) then $natural-end-item else $count

for $j in ($start-item to $actual-end-item )
let $current := item-at($results, $j)
return
 <document-summary
    requested-page-nbr="{$requested-page-nbr}"
    items-per-page="{$items-per-page}"
    count="{$count}"
    last-page-nbr="{$last-page-nbr}"
    actual-page-nbr="{$actual-page-nbr}"
    start-item="{$start-item}"
    natural-end-item="{$natural-end-item}"
    actual-end-item="{$actual-end-item}">
  {($current)}
 </document-summary>
}</result>

Answer 1

Я не думаю, что это правильный способ XQuery ...

Этот XQuery:

declare variable $requested-page-nbr external;
declare variable $items-per-page external;
declare variable $items := /root/item;
declare variable $firsties := $items[position() mod $items-per-page = 1];
for $first in $firsties 
let $actual-page-nbr := index-of($firsties,$first)
let $group := $first|
              $first/following-sibling::item[position() < $items-per-page]
let $previous := ($actual-page-nbr - 1) * $items-per-page
where $actual-page-nbr = $requested-page-nbr
return
<result>
    <document-summary requested-page-nbr="{$requested-page-nbr}" 
                      items-per-page="{$items-per-page}" 
                      count="{count($items)}" 
                      last-page-nbr="{count($firsties)}" 
                      actual-page-nbr="{$actual-page-nbr}" 
                      start-item="{$previous + 1}" 
                      natural-end-item="{$previous + $items-per-page}" 
                      actual-end-item="{$previous + count($group)}">{ 
       $group 
   }</document-summary> 
</result> 

С этим входом:

<root>
    <item>1</item>
    <item>2</item>
    <item>3</item>
    <item>4</item>
    <item>5</item>
    <item>6</item>
    <item>7</item>
    <item>8</item>
    <item>9</item>
    <item>10</item>
    <item>11</item>
    <item>12</item>
    <item>13</item>
</root>

Сзапрашиваемая страница-nbr установлена ​​в 2, а $ items-per-page установлена ​​в 3, выводится:

<result>
    <document-summary requested-page-nbr="2"
                      items-per-page="3"
                      count="13"
                      last-page-nbr="5"
                      actual-page-nbr="2"
                      start-item="4"
                      natural-end-item="6"
                      actual-end-item="6">
        <item>4</item>
        <item>5</item>
        <item>6</item>
    </document-summary>
</result>

С $ required-page-nbr установлен в 4 и $ items-per-page установлен в 4, выход:

<result>
    <document-summary requested-page-nbr="4"
                      items-per-page="4"
                      count="13"
                      last-page-nbr="4"
                      actual-page-nbr="4"
                      start-item="13"
                      natural-end-item="16"
                      actual-end-item="13">
        <item>13</item>
    </document-summary>
</result>

Answer 2

Что касается возврата «страницы» результатов, где вы используете

{($ тока)}

мы используем что-то вроде следующего

{подпоследовательность ($ results, $ start-item, $ items-per-page)}

Answer 3

чтобы добавить атрибут в корень:

<result>{attribute page {3}}</result>

в вашем случае вы, вероятно, захотите сделать что-то вроде: (?)

...
return ( 
  attribute page {$actual-page-nbr},

  for $j in ($start-item to $actual-end-item )
  let $current := item-at($results, $j)
  return
    <document-summary
       requested-page-nbr="{$requested-page-nbr}"
       items-per-page="{$items-per-page}"
       count="{$count}"
       last-page-nbr="{$last-page-nbr}"
       actual-page-nbr="{$actual-page-nbr}"
       start-item="{$start-item}"
       natural-end-item="{$natural-end-item}"
       actual-end-item="{$actual-end-item}">
     {($current)}
    </document-summary>)
...

это отвечает на ваш вопрос?