Как получить все ошибки и сообщения из запроса с помощью ADO - PullRequest
Новая
       4

Как получить все ошибки и сообщения из запроса с помощью ADO

2 голосов
/ 10 июня 2010

Когда пакет SQL возвращает более одного сообщения, например, от печатать операторы, тогда я могу получить только первый, используя коллекцию ошибок ADO-соединения. Как получить остальные сообщения?

Если я запускаю этот скрипт: 

Option Explicit
Dim conn
Set conn = CreateObject("ADODB.Connection")
conn.Provider = "SQLOLEDB"
conn.ConnectionString = "Data Source=(local);Integrated Security=SSPI;Initial Catalog=Master"
conn.Open

conn.Execute("print 'Foo'" & vbCrLf & "print 'Bar'" & vbCrLf & "raiserror ('xyz', 10, 127)")

Dim error
For Each error in conn.Errors
    MsgBox error.Description
Next

Тогда я получаю только "Foo", а не "Bar" или "xyz".

Есть ли способ получить оставшиеся сообщения?

1 Ответ

6 голосов
/ 10 июня 2010

Я понял это самостоятельно.

Это работает: 

Option Explicit
Dim conn
Set conn = CreateObject("ADODB.Connection")
conn.Provider = "SQLOLEDB"
conn.ConnectionString = "Data Source=(local);Integrated Security=SSPI;Initial Catalog=Master"
conn.Open

Dim rs
Set rs = conn.Execute("print 'Foo'" & vbCrLf & "print 'Bar'" & vbCrLf & "raiserror ('xyz', 10, 127)")

Dim error
While not (rs is nothing)
    For Each error in conn.Errors
        MsgBox error.Description
    Next
    Set rs = rs.NextRecordSet
Wend
...