Ошибка при сопоставлении элементов XML с атрибутом пространства имен

Question

Как будет выглядеть условный оператор, если я вставлю фрагмент текста в xml ниже с помощью xslt?

<items xmlns="http://mynamespace.com/definition">
    <item>
        <number id="1"/>
    </item>
    <item>
        <number id="2"/>
    </item>
    <!-- insert the below text -->
    <reference>
        <refNo id="a"/>
        <refNo id="b"/>
    </reference>
    <!-- end insert -->
</items>

Вот так выглядит мой xsl на данный момент (условие неверное ...):

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://mynamespace.com/definition"
    version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:param name="addRef">
        <reference>
            <refNo id="a"/>
            <refNo id="b"/>
        </reference>
    </xsl:param>
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <!-- here is where the condition got stuck... -->
    <xsl:template match="/items[namespace-url()=*]/item[position()=last()]">
        <xsl:call-template name="identity"/>
        <xsl:copy-of select="$addRef"/>
    </xsl:template>
</xsl:stylesheet>

Я хотел добавить справочный раздел после самого нижнего, но я застрял в том, как обойти сопоставление элемента, который имеет (явное) пространство имен.

Спасибо.

Answer 1

Лучшим и более элегантным способом решения этой проблемы было бы использование префикса для вашего пространства имен. Я предпочитаю работать с пустым пространством имен по умолчанию и использовать префиксы для всех определенных пространств имен.

Соответствие fn:local-name() будет соответствовать локальному имени узла во всех пространствах имен. Все, что необходимо в вашем условии соответствия, если префикс для вашего пространства имен - my:item[last()].

Введите:

<?xml version="1.0" encoding="UTF-8"?>
<items xmlns="http://mynamespace.com/definition">
  <item>
    <number id="1"/>
  </item>
  <item>
    <number id="2"/>
  </item>
</items>

XSLT:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:my="http://mynamespace.com/definition">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

  <xsl:param name="addRef">
    <!-- We set the default namespace to your namespace for this
         certain result tree fragment. -->
    <reference xmlns="http://mynamespace.com/definition">
      <refNo id="a"/>
      <refNo id="b"/>
    </reference>
  </xsl:param>

  <xsl:template match="node()|@*" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="my:item[last()]">
    <xsl:call-template name="identity"/>
    <xsl:copy-of select="$addRef"/>
  </xsl:template>

</xsl:stylesheet>

Выход:

<?xml version="1.0" encoding="UTF-8"?>
<items xmlns="http://mynamespace.com/definition">
  <item>
    <number id="1"/>
  </item>
  <item>
    <number id="2"/>
  </item>
  <reference>
    <refNo id="a"/>
    <refNo id="b"/>
  </reference>
</items>

Answer 2

Попробуйте это:

match="//*[local-name()='items']/*[local-name()='item'][position()=last()]"