Как я также могу получить индекс элемента, когда я grep через массив?

Question

Допустим, у меня есть этот список:

my @list = qw(one two three four five);

и я хочу получить все элементы, содержащие o. Я бы получил это:

my @containing_o = grep { /o/ } @list;

Но что мне нужно сделать, чтобы также получить индекс или получить доступ к индексу в теле grep?

Answer 1

my @index_containing_o = grep { $list[$_] =~ /o/ } 0..$#list;  # ==> (0,1,3)

my %hash_of_containing_o = map { $list[$_]=~/o/?($list[$_]=>$_):() } 0..$#list
            # ==> ( 'one' => 0, 'two' => 1, 'four' => 3 )

Answer 2

Взгляните на Список :: MoreUtils . Вы можете делать много полезных вещей с массивами, не катя собственную версию, плюс она быстрее (потому что она реализована в C / XS):

use List::MoreUtils qw(first_index indexes);

my $index_of_matching_element = first_index { /o/ } @list;

Для всех соответствующих индексов и соответствующих им элементов вы можете сделать:

my @matching_indices = indexes { /o/ } @list;
my @matching_values = @list[@matching_indices];

или просто:

my @matching_values = grep { /o/ } @list;

Answer 3

Заполняет 2 массива тем, что вам нужно, и циклически перебирает входной массив:

use strict;
use warnings;
my @list = qw(one two three four five);
my @containing_o;
my @indexes_o;
for (0 .. $#list) {
    if ($list[$_] =~ /o/) {
        push @containing_o, $list[$_];
        push @indexes_o   , $_;
    }
}