Выполнение манипуляций с путями к файлам в XSLT - PullRequest
Новая
       9

Выполнение манипуляций с путями к файлам в XSLT

7 голосов
/ 25 июня 2010

Я бы хотел, чтобы мой сгенерированный выходной файл содержал пути к файлам, которые указывают на путь относительно таблицы стилей. Расположение таблицы стилей может измениться, и я не хочу использовать параметр для таблицы стилей. Мое решение для этого состоит в том, чтобы получить полный URI таблицы стилей: 

<xsl:variable name="stylesheetURI" select="document-uri(document(''))" />

Теперь мне нужно только отрезать имя файла от $stylesheetURI. Это вдохновило меня на написание XSLT 2.0 клонов функций PHP basename и dirname : 

<xsl:function name="de:basename">
    <xsl:param name="file"></xsl:param>
    <xsl:sequence select="tokenize($file, '/')[last()]" />
</xsl:function>

<xsl:function name="de:dirname">
    <xsl:param name="file"></xsl:param>
    <xsl:sequence 
        select="string-join(tokenize($file, '/')[position() != last()], '/')" />
</xsl:function>

Теперь я могу сделать что-то подобное в моем шаблоне: 

<img src="{concat(de:dirname($stylesheetURI),'/img/myimage,png')}" />

Мой вопрос: есть ли лучшие / более быстрые способы сделать это с помощью родного XSLT 2.0?

1 Ответ

8 голосов
/ 25 июня 2010

Я тестировал (не слишком широко) эти функции , и они , кажется, работают на 25% быстрее , чем предусмотрено.Конечно, результаты зависят от длины строки и количества квалификаторов: 

  <xsl:function name="de:basename" as="xs:string">
    <xsl:param name="pfile" as="xs:string"/>
    <xsl:sequence select=
     "de:reverseStr(substring-before(de:reverseStr($pfile), '/'))
     " />
  </xsl:function>

  <xsl:function name="de:dirname" as="xs:string">
    <xsl:param name="pfile" as="xs:string"/>
    <xsl:sequence select=
     "de:reverseStr(substring-after(de:reverseStr($pfile), '/'))
     " />
  </xsl:function>

  <xsl:function name="de:reverseStr" as="xs:string">
    <xsl:param name="pStr" as="xs:string"/>

    <xsl:sequence select=
    "codepoints-to-string(reverse(string-to-codepoints($pStr)))"/>
  </xsl:function>
...