GroovyWS и сложные запросы

Question

Я столкнулся с проблемой отправки сложных запросов с GroovyWS.

Это пример запроса, созданного soapUI:

<soapenv:Envelope 
    xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
    xmlns:dex="http://www.temp.com/com/dex" 
>
 <soapenv:Header/>
 <soapenv:Body>
  <dex:executeRequest>
     <!--Optional:-->
     <a>?</a>
     <!--Optional:-->
     <b>?</b>
     <!--Optional:-->
     <parameters>
        <!--Zero or more repetitions:-->
        <parameter>
           <!--Optional:-->
           <key>?</key>
           <!--Optional:-->
           <value>?</value>
        </parameter>
     </parameters>
     <!--Optional:-->
     <c>?</c>
     <!--Optional:-->
     <d>?</d>
  </dex:feedrequest>
 </soapenv:Body>
</soapenv:Envelope>

кусок шпунтового кода:

def proxy = webService.getClient(grailsApplication.config.ws.endpoint);
proxy.processdRequest(?);

Так что я должен передать вместо ? .

Спасибо за помощь.

-vova.

Answer 1

GroovyWS динамически создает классы для каждого из типов аргументов, которые вам нужны для передачи данных в вызов веб-службы. Например, если вызов веб-службы был:

public int passSomeArgs( Arg1Type a, Arg2Type b );

GroovyWS будет динамически создавать класс Arg1Type и класс Arg2Type, к которым вы можете получить доступ через метод прокси.

// this will instantiate an Arg1Type for you
def arg1 = proxy.create( "ns1.ns2.Arg1Type" );  
// this will instantiate an Arg2Type for you
def arg2 = proxy.create( "ns1.ns2.Arg2Type" );  

Затем вы можете заполнить экземпляр arg1 / arg2 данными и сделать ваш вызов:

int ret = proxy.passSomeArgs( arg1, arg2 );

Обратите внимание, что в создаваемых классах, возможно, есть несколько пространств имен. Я использовал протоколирование CXF, которое было напечатано, когда GroovyWS обрабатывал WSDL, чтобы увидеть, что, по мнению CXF, должны действительно называться имена классов.

Answer 2

Большое спасибо, Билл.

Я просто хочу добавить информацию для будущих читателей.

Чтобы включить ведение журнала для GroovyWS в Grails:

log4j = {
   debug 'grails.app',
         'groovyx.net.ws',
         'org.apache.cxf'
}

С этим, как уже упоминалось, Биллом вы можете видеть названия классов.

Еще одна вещь: parameters может иметь другой тип. Не List<?>. Вот почему это должно быть создано тоже.

def params = proxy.create('com.temp.feeds.FeedRequestType$Parameters');

Чтобы получить доступные методы и поля для вновь созданных объектов, вы можете использовать Groovy отражение:

params.class.methods.each{
        println it;
}
params.class.fields.each{
        println it;
}

Вот и все!

-vova

Answer 3

Спасибо!GroovyWS работает с очень сложным веб-сервисом!

Мои шаги: я включил отладку, чтобы получить корневой класс, затем сделал этот код отражения, чтобы получить внутренние классы, и приступил к настройке свойств и проверке, является ли это строкойили список.

И вуаля!

def proxy = new WSClient(wsdl,this.class.classLoader)
proxy.initialize()

def f2bCobranca = proxy.create("br.com.f2b.soap.wsbilling.F2BCobranca") //got with debug on

//Show me inner classes of root class
f2bCobranca.class.fields.each { log.debug it }
f2bCobranca.class.methods.each { log.debug it }

f2bCobranca.cobranca = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Cobranca')
f2bCobranca.cobranca.demonstrativo << 'teste' //it's a list!
f2bCobranca.cobranca.sacadorAvalista = 'teste jose'
f2bCobranca.cobranca.desconto = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Cobranca$Desconto')
f2bCobranca.cobranca.multa = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Cobranca$Multa')

def sacado1 = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Sacado')
sacado1.nome = "teste ${new Date()}"
sacado1.email << 'teste@wanswins.com.br'
sacado1.endereco = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Sacado$Endereco')
sacado1.telefone = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Sacado$Telefone')
sacado1.telefoneCom = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Sacado$TelefoneCom')
sacado1.telefoneCel = proxy.create('br.com.f2b.soap.wsbilling.F2BCobranca$Sacado$TelefoneCel')
sacado1.cpf = ''
sacado1.cnpj = ''
sacado1.observacao = ''
f2bCobranca.sacado << sacado1  

def retorno = proxy.RegisterWSBilling(f2bCobranca)
log.debug retorno