Соответствие лексемных вариантов с Antlr3

Question

Я пытаюсь сопоставить измерения в английском тексте ввода, используя Antlr 3.2 и Java1.6.У меня есть лексические правила, такие как:

fragment
MILLIMETRE
    :   'millimetre' | 'millimetres'
    |   'millimeter' | 'millimeters'
    |   'mm'
    ;

MEASUREMENT
    :   MILLIMETRE | CENTIMETRE | ... ;

Я бы хотел принять любую комбинацию ввода прописных и строчных букв и, что более важно, просто вернуть один лексический токен для всехварианты МИЛЛИМЕТРА.Но на данный момент мой AST содержит «миллиметр», «миллиметр», «мм» и т. Д., Как во входном тексте.

После прочтения http://www.antlr.org/wiki/pages/viewpage.action?pageId=1802308, я думаю, что мне нужно сделать что-то вродеследующее:

tokens {
    T_MILLIMETRE;
}

fragment
MILLIMETRE
    :   ('millimetre' | 'millimetres'
    |   'millimeter' | 'millimeters'
    |   'mm') { $type = T_MILLIMETRE; }
    ;

Однако, когда я делаю это, я получаю следующие ошибки компилятора в коде Java, сгенерированном Antlr:

cannot find symbol
_type = T_MILLIMETRE;

Вместо этого я попробовал следующее:

MEASUREMENT
    :   MILLIMETRE  { $type = T_MILLIMETRE; }
    |   ...

но тогда ИЗМЕРЕНИЕ больше не сопоставляется.

Более очевидное решение с правилом перезаписи:

MEASUREMENT
    :   MILLIMETRE  -> ^(T_MILLIMETRE MILLIMETRE)
    |   ...

вызывает NPE:

java.lang.NullPointerException at org.antlr.grammar.v2.DefineGrammarItemsWalker.alternative(DefineGrammarItemsWalker.java:1555).

Превращение ИЗМЕРЕНИЯ в правило синтаксического анализатора вызывает у меня ужас: «Следующие определения токенов никогда не могут быть сопоставлены, поскольку предыдущие токены совпадают с одним и тем же входным сигналом».* Я получаю предупреждение "нет правила лексера, соответствующего токену: T_MILLIMETRE".Хотя Antlr запускается, но он все равно дает мне входной текст в AST, а не в T_MILLIMETRE.

Я, очевидно, еще не вижу мир, как это делает Antlr.Кто-нибудь может дать мне какие-нибудь советы или советы, пожалуйста?

Стив

Answer 1

Вот способ сделать это:

grammar Measurement;

options {
  output=AST;
}

tokens {
  ROOT;
  MM;
  CM;
}

parse
  :  measurement+ EOF -> ^(ROOT measurement+)
  ;

measurement
  :  Number MilliMeter -> ^(MM Number)
  |  Number CentiMeter -> ^(CM Number)
  ;

Number
  :  '0'..'9'+
  ;

MilliMeter
  :  'millimetre'
  |  'millimetres'
  |  'millimeter'
  |  'millimeters'
  |  'mm'
  ;

CentiMeter
  :  'centimetre'
  |  'centimetres'
  |  'centimeter'
  |  'centimeters'
  |  'cm'
  ;

Space
  :  (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;}
  ;

Его можно протестировать с помощью следующего класса:

import org.antlr.runtime.*;
import org.antlr.runtime.tree.*;
import org.antlr.stringtemplate.*;

public class Main {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12 millimeters 3 mm 456 cm");
        MeasurementLexer lexer = new MeasurementLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        MeasurementParser parser = new MeasurementParser(tokens);
        MeasurementParser.parse_return returnValue = parser.parse();
        CommonTree tree = (CommonTree)returnValue.getTree();
        DOTTreeGenerator gen = new DOTTreeGenerator();
        StringTemplate st = gen.toDOT(tree);
        System.out.println(st);
    }
}

, который создает следующий файл DOT:

digraph {

    ordering=out;
    ranksep=.4;
    bgcolor="lightgrey"; node [shape=box, fixedsize=false, fontsize=12, fontname="Helvetica-bold", fontcolor="blue"
        width=.25, height=.25, color="black", fillcolor="white", style="filled, solid, bold"];
    edge [arrowsize=.5, color="black", style="bold"]

  n0 [label="ROOT"];
  n1 [label="MM"];
  n1 [label="MM"];
  n2 [label="12"];
  n3 [label="MM"];
  n3 [label="MM"];
  n4 [label="3"];
  n5 [label="CM"];
  n5 [label="CM"];
  n6 [label="456"];

  n0 -> n1 // "ROOT" -> "MM"
  n1 -> n2 // "MM" -> "12"
  n0 -> n3 // "ROOT" -> "MM"
  n3 -> n4 // "MM" -> "3"
  n0 -> n5 // "ROOT" -> "CM"
  n5 -> n6 // "CM" -> "456"

}

, которое соответствует дереву:

(изображение, созданное http://graph.gafol.net/)

РЕДАКТИРОВАТЬ

Обратите внимание, что следующее:

measurement
  :  Number m=MilliMeter {System.out.println($m.getType() == MeasurementParser.MilliMeter);}
  |  Number CentiMeter
  ;

всегда будет печатать true, независимо от того, являются ли «содержимое» (миллиметровых) токенов mm, millimetre, millimetres, ...

Answer 2

Обратите внимание, что fragment правила только "живут" внутри лексера и перестают существовать в парсере.Например:

grammar Measurement;

options {
  output=AST;
}

parse
  :  (m=MEASUREMENT {
       String contents = $m.text;
       boolean isMeasurementType = $m.getType() == MeasurementParser.MEASUREMENT;
       System.out.println("contents="+contents+", isMeasurementType="+isMeasurementType);
     })+ EOF
  ;

MEASUREMENT
  :  MILLIMETRE
  ;

fragment
MILLIMETRE
  :  'millimetre' 
  |  'millimetres'
  |  'millimeter' 
  |  'millimeters'
  |  'mm'
  ;

SPACE
  :  (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;}
  ;

с вводимым текстом:

"millimeters mm"

напечатает:

contents=millimeters, isMeasurementType=true
contents=mm, isMeasurementType=true

другими словами: тип MILLIMETRE не существует,они все типа MEASUREMENT.