Как сгруппировать записи в ведро на основе отметки времени? - PullRequest
Новая
       28

Как сгруппировать записи в ведро на основе отметки времени?

0 голосов
/ 10 июля 2010

У меня есть список записей из журналов: 

15:38:52.363 1031
15:41:06.347 1259
15:41:06.597 1171
15:48:44.115 1588
15:48:44.125 1366
15:48:44.125 1132
15:53:14.525 1348
15:53:15.121 1553
15:53:15.181 1286
15:53:15.187 1293

первая - это отметка времени, вторая - это значение.

Теперь я пытаюсь сгруппировать их, скажем, через 20 секунд. Я хочу либо суммировать значения, либо получить их среднее значение. Интересно, какой самый простой способ сделать это? желательно, чтобы я мог сделать это с помощью простого сценария оболочки, чтобы я мог передать свой оператор grep и получить разделенный список. спасибо!

1 Ответ

1 голос
/ 10 июля 2010

Этот скрипт gawk полностью игнорирует доли секунды.Он также ничего не знает о переходе от одного дня к следующему (пересечение 00:00:00): 

grep ... | awk -v interval=20 'function groupout() {print "----", "Timespan ending:", strftime("%T", prevtime), "Sum:", sum, "Avg:", sum/count, "----"} BEGIN {prevtime = 0} {split($1, a, "[:.]"); time = mktime(strftime("%Y %m %d") " " a[1] " " a[2] " " a[3]); if (time > prevtime + interval) {if (NR != 1) {groupout(); sum=0; count=0}}; print; sum+=$2; count++; prevtime = time} END {groupout()}'

Вывод: 

15:38:52.363 1031
---- Timespan ending: 15:38:52 Sum: 1031 Avg: 1031 ----
15:41:06.347 1259
15:41:06.597 1171
---- Timespan ending: 15:41:06 Sum: 2430 Avg: 1215 ----
15:48:44.115 1588
15:48:44.125 1366
15:48:44.125 1132
---- Timespan ending: 15:48:44 Sum: 4086 Avg: 1362 ----
15:53:14.525 1348
15:53:15.121 1553
15:53:15.181 1286
15:53:15.187 1293
---- Timespan ending: 15:53:15 Sum: 5480 Avg: 1370 ----

Здесь это снова более наглядно: 

awk -v interval=20 '
function groupout() {
    print "----", "Timespan ending:", strftime("%T", prevtime), "Sum:", sum, "Avg:", sum/count, "----"
}
BEGIN {
    prevtime = 0
} 
{
    split($1, a, "[:.]"); 
    time = mktime(strftime("%Y %m %d") " " a[1] " " a[2] " " a[3]); 
    if (time > prevtime + interval) {
        if (NR != 1) {groupout(); sum=0; count=0}
    }; 
    print; 
    sum+=$2; 
    count++; 
    prevtime = time
} 
END {groupout()}'
...