Как переименовать открытый файл в Emacs?

Question

Есть ли способ переименовать открытый файл в Emacs? Пока я это просматриваю? Что-то вроде save-as, но оригинал должен исчезнуть.

Answer 1

Да, в режиме dired вы можете:

• C-x d чтобы открыть dired
• RET для выбора каталога текущего файла
• C-x C-j (dired-jump к имени текущего файла, в Dired)
• R для переименования файла (или dired-do-rename).
• q для возврата в (переименованный) файловый буфер

Переименование эквивалентно оболочке mv, но оно также обновит все открытые буферы.

Answer 2

Просто для полноты, поскольку некоторые люди могут посещать эту страницу, думая, что они получат ответ на функцию "сохранить как" в Emacs, это C-x C-w для открытого файла.

Answer 3

Попробуйте эту функцию из .emacs Стива Йегге :

;; source: http://steve.yegge.googlepages.com/my-dot-emacs-file
(defun rename-file-and-buffer (new-name)
  "Renames both current buffer and file it's visiting to NEW-NAME."
  (interactive "sNew name: ")
  (let ((name (buffer-name))
        (filename (buffer-file-name)))
    (if (not filename)
        (message "Buffer '%s' is not visiting a file!" name)
      (if (get-buffer new-name)
          (message "A buffer named '%s' already exists!" new-name)
        (progn
          (rename-file filename new-name 1)
          (rename-buffer new-name)
          (set-visited-file-name new-name)
          (set-buffer-modified-p nil))))))

Взгляните на эту страницу, там есть еще одна действительно полезная функция, которая называется "move-buffer-file".

Answer 4

Мой любимый - один из "Магнаров" (из скриншотов Emacs Rock Fame.)

В отличие от других альтернатив, вам не нужно вводить имя с нуля - вы можете изменить текущее имя.

(defun rename-current-buffer-file ()
  "Renames current buffer and file it is visiting."
  (interactive)
  (let* ((name (buffer-name))
        (filename (buffer-file-name))
        (basename (file-name-nondirectory filename)))
    (if (not (and filename (file-exists-p filename)))
        (error "Buffer '%s' is not visiting a file!" name)
      (let ((new-name (read-file-name "New name: " (file-name-directory filename) basename nil basename)))
        (if (get-buffer new-name)
            (error "A buffer named '%s' already exists!" new-name)
          (rename-file filename new-name 1)
          (rename-buffer new-name)
          (set-visited-file-name new-name)
          (set-buffer-modified-p nil)
          (message "File '%s' successfully renamed to '%s'"
                   name (file-name-nondirectory new-name)))))))

Спасибо Джеймсу Яну за правильную версию.

Answer 5

Вот более надежная версия, адаптированная от Stevey.

;; Originally from stevey, adapted to support moving to a new directory.
(defun rename-file-and-buffer (new-name)
  "Renames both current buffer and file it's visiting to NEW-NAME."
  (interactive
   (progn
     (if (not (buffer-file-name))
         (error "Buffer '%s' is not visiting a file!" (buffer-name)))
     ;; Disable ido auto merge since it too frequently jumps back to the original
     ;; file name if you pause while typing. Reenable with C-z C-z in the prompt.
     (let ((ido-auto-merge-work-directories-length -1))
       (list (read-file-name (format "Rename %s to: " (file-name-nondirectory
                                                       (buffer-file-name))))))))
  (if (equal new-name "")
      (error "Aborted rename"))
  (setq new-name (if (file-directory-p new-name)
                     (expand-file-name (file-name-nondirectory
                                        (buffer-file-name))
                                       new-name)
                   (expand-file-name new-name)))
  ;; Only rename if the file was saved before. Update the
  ;; buffer name and visited file in all cases.
  (if (file-exists-p (buffer-file-name))
      (rename-file (buffer-file-name) new-name 1))
  (let ((was-modified (buffer-modified-p)))
    ;; This also renames the buffer, and works with uniquify
    (set-visited-file-name new-name)
    (if was-modified
        (save-buffer)
      ;; Clear buffer-modified flag caused by set-visited-file-name
      (set-buffer-modified-p nil)))

  (setq default-directory (file-name-directory new-name))

  (message "Renamed to %s." new-name))

Answer 6

Вот еще одна версия, довольно надежная и осведомленная VC:

(defun rename-file-and-buffer ()
  "Rename the current buffer and file it is visiting."
  (interactive)
  (let ((filename (buffer-file-name)))
    (if (not (and filename (file-exists-p filename)))
        (message "Buffer is not visiting a file!")
      (let ((new-name (read-file-name "New name: " filename)))
        (cond
         ((vc-backend filename) (vc-rename-file filename new-name))
         (t
          (rename-file filename new-name t)
          (set-visited-file-name new-name t t)))))))

Подробнее об этом можно прочитать здесь .

Answer 7

Есть очень простой способ, вы нажимаете команду Mx и затем набираете vc-rename-file , после чего вам просто нужно выбрать текущий файл в каталоге, и чем выбрать новое имя. Бафф с измененным файлом будет обновлен.

* Источник: 1008 *https://www.gnu.org/software/emacs/manual/html_node/emacs/VC-Delete_002fRename.html

Answer 8

в зависимости от версии магнаров, я изменил, как показано ниже, исправил часть имени файла INIT:

(defun rename-current-buffer-file ()
  "Renames current buffer and file it is visiting."
  (interactive)
  (let* ((name (buffer-name))
        (filename (buffer-file-name))
        (basename (file-name-nondirectory filename)))
    (if (not (and filename (file-exists-p filename)))
        (error "Buffer '%s' is not visiting a file!" name)
      (let ((new-name (read-file-name "New name: " (file-name-directory filename) basename nil basename)))
        (if (get-buffer new-name)
            (error "A buffer named '%s' already exists!" new-name)
          (rename-file filename new-name 1)
          (rename-buffer new-name)
          (set-visited-file-name new-name)
          (set-buffer-modified-p nil)
          (message "File '%s' successfully renamed to '%s'"
                   name (file-name-nondirectory new-name)))))))

Answer 9

Если вы используете Spacemacs , тогда вы получаете это поведение бесплатно, поскольку оно поставляется с реализацией rename-current-buffer-file (на основе магнаров), которая по умолчанию связана с SPC-f-R.

https://github.com/syl20bnr/spacemacs/blob/bd7ef98e4c35fd87538dd2a81356cc83f5fd02f3/layers/%2Bdistributions/spacemacs-base/funcs.el#L294

Answer 10

Это может быть достигнуто путем копирования. shift + c для файла, и emacs попросит вас указать имя пути, включая имя файла, поэтому вы просто указываете новое имя и вводите ... конечно, вы должны удалить предыдущее.