Как получить индекс элемента в массиве?

Question

Есть ли в Perl встроенная функция для получения индекса элемента в массиве?Или мне нужно написать такую ​​функцию самостоятельно?[эквивалентно PHP array_search () или JavaScript array.indexOf ()]

Answer 1

use List::Util qw(first);
$idx = first { $array[$_] eq 'whatever' } 0..$#array;

(список :: Util является основным)

или

use List::MoreUtils qw(firstidx);
$idx = firstidx { $_ eq 'whatever' } @array;

(List :: MoreUtils на CPAN)

Answer 2

Вот способ сделать это после 5.10, с дополнительным преимуществом определения того, сколько индексов соответствует данному значению.

my @matches = grep { $array[$_] ~~ $element } 0 .. $#array;

Если все элементы гарантированно являются уникальными или только первый индекспредставляет интерес:

my ($index) = grep { $array[$_] ~~ $element } 0 .. $#array;

Answer 3

Вот решение autobox:

use autobox::Core;

my @things = qw/blue black green red green yellow/;

my $first_green = @things->first_index( sub{ $_[0] eq 'green' } ); # code block
my $last_green  = @things->last_index ( qr/^green$/ );             # or regex

say $first_green;    # => 2
say $last_green;     # => 4

Answer 4

Для этого можно написать функцию:

sub array_search {
    my ($arr, $elem) = @_;
    my $idx;
    for my $i (0..$#$arr) {
        if ($arr->[$i] eq $elem) {
            $idx = $i;
            last;
        }
    }
    return $idx;            
}

Будет возвращен индекс первого соответствующего элемента или undef.