Как мне преобразовать число в повторение символов в XSLT? - PullRequest
Новая
       35

Как мне преобразовать число в повторение символов в XSLT?

2 голосов
/ 27 ноября 2008

У меня есть следующий ввод: 

<node TEXT="txt">
  <node TEXT="txt">
    <node TEXT="txt"/>
    <node TEXT="txt"/>
  </node>
  <node TEXT="txt"/>
</node>
<node TEXT="txt"/>

Я сейчас использую: 

<xsl:number level="multiple" count="node" format="1"/>

в сценарии XSTL для получения следующего вывода: 

1 txt
1.1 txt
1.1.1 txt
1.1.2 txt
1.2 txt
2 txt

но я хочу получить такой вывод: 

* txt
** txt
*** txt
*** txt
** txt
* txt

Вы можете мне помочь?

PS: Я хочу преобразовать карту свободного разума в базовый синтаксис списка вики. И да! я знаю, что есть несколько способов получить нативные карты freemind в медиа-вики, но мне нужно преобразование <node> -дерева в *** -списки

1 Ответ

2 голосов
/ 27 ноября 2008

Один простой способ сделать это - просто перевести результат 

<xsl:number/>
в нужный формат.

Это преобразование:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:strip-space elements="*"/>

<xsl:template match="node">
  <xsl:variable name="vIndent">
    <xsl:number level="multiple" count="node"/>
  </xsl:variable>

  <xsl:value-of select=
   "concat(translate($vIndent,
                     '1234567890.',
                     '**********'),
           ' ',
           @TEXT,
         '&#xA;'
         )"/>
 <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

при применении к этому документу XML: 

<t>
    <node TEXT="txt">
        <node TEXT="txt">
            <node TEXT="txt"/>
            <node TEXT="txt"/></node>
        <node TEXT="txt"/></node>
    <node TEXT="txt"/>
</t>

дает желаемый результат: 

* txt
** txt
*** txt
*** txt
** txt
* txt

Обратите внимание на использование функции translate () для удаления любого символа "." символов и для перевода любой цифры в "*".

...