вернуть список всех макросов - PullRequest
Новая
       4

вернуть список всех макросов

0 голосов
/ 13 октября 2010

В vba, как я могу вызвать документ word и получить список всех макросов, которые он содержит?

1 Ответ

0 голосов
/ 13 октября 2010

Эта статья должна показать вам, как это сделать (это для Word 2000, но я предполагаю, что есть большая вероятность, что она будет работать для любой используемой вами версии): WD2000: пример макроса для возврата имен макросов и процедур

Это код из этой статьи: 

Sub ListAllMacroNames()

Dim pj As VBProject
Dim vbcomp As VBComponent
Dim curMacro As String, newMacro As String
Dim x As String
Dim y As String

On Error Resume Next
curMacro = ""
Documents.Add

For Each pj In Application.VBE.VBProjects
   x = pj.FileName
   y = pj.Protection

   If x <> "" Then

      If y <> "1" Then
         Selection.InsertAfter "The " & Chr(34) & x & Chr(34) & _
            " project contains " & "the following macro names:" & vbCr
         Selection.InsertAfter vbCr

         For Each vbcomp In pj.VBComponents

            For i = 1 To vbcomp.CodeModule.CountOfLines
               newMacro = vbcomp.CodeModule.ProcOfLine(Line:=i, _
                  prockind:=vbext_pk_Proc)

               If curMacro <> newMacro Then
                  curMacro = newMacro

                  If curMacro <> "" And curMacro <> "app_NewDocument" Then
                        Selection.InsertAfter newMacro & vbCr
                        Selection.Collapse wdCollapseEnd
                     End If
               End If
            Next
         Next
     Else
        Selection.InsertAfter "The project " & Chr(34) & x & Chr(34) & _
           " is locked. " & "Macros in this locked project will not be" _
           & " listed." & vbCr & vbCr
     End If
     Selection.InsertAfter vbCr
   End If
   x = ""
Next
Selection.Collapse wdCollapseEnd
End Sub
...