Как отформатировать дату и время с минимальными разделителями и часовым поясом в VBScript? - PullRequest
Новая
       38

Как отформатировать дату и время с минимальными разделителями и часовым поясом в VBScript?

4 голосов
/ 06 августа 2010

У меня есть следующий код в C #: 

DateTime dt = GetDateTime();
string formatted = dt.ToString("yyyyMMddTHHmmsszz");

, который возвращает дату в следующем формате: 

20100806T112917+01

Я хотел бы получить такие же результаты в VBScript (для устаревшего приложения ASP). Особенно важно, чтобы я получил информацию о смещении UTC или преобразовал время в UTC.

Как мне это сделать?

Ответы [ 2 ]

8 голосов
/ 07 августа 2010

Для форматирования даты мне нравится использовать класс .NET StringBuilder из VBScript: 

Option Explicit

Dim sb : Set sb = CreateObject("System.Text.StringBuilder")
sb.AppendFormat "{0:yyyyMMddTHHmmsszz}", Now()
Response.Write sb.ToString()

Вышеуказанное возвращает: 

20100806T201139-07

Это предполагает, что у вас установлен .NETвеб-сервер.

2 голосов
/ 06 августа 2010

Вот моя собственная попытка.Лучшие решения будут любезно приняты! 

Function ToDateTimeStringMinimalSeparators(dateTime)

    ' --------------------------------------------------------------------------
    '  F O R M A T   T H E   U T C   O F F S E T
    ' --------------------------------------------------------------------------

    Dim oShell, activeTimeBias
    Set oShell = CreateObject("WScript.Shell")
    activeTimeBias = oShell.RegRead("HKEY_LOCAL_MACHINE\System\" & _
        "CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")

    Dim sign
    sign = "-"
    If activeTimeBias < 0 Then
        sign = "+"
        ' Make it positive while we're doing calculations
        activeTimeBias = activeTimeBias * -1
    End If

    Dim atbHours, atbMins
    atbHours = Right("00" & Int(activeTimeBias / 60), 2)
    atbMins = Right("00" & (activeTimeBias Mod 60), 2)
    If atbMins = "00" Then
        atbMins = ""
    End If

    Dim utcOffset
    utcOffset = sign & atbHours & atbMins

    ' --------------------------------------------------------------------------
    '  F O R M A T   T H E   M A I N   D A T E
    ' --------------------------------------------------------------------------

    Dim dateBody
    dateBody = Right("0000" & Year(dateTime), 4) & _
        Right("00" & Month(dateTime), 2) & _
        Right("00" & Day(dateTime), 2) & _
        "T" & _
        Right("00" & Hour(dateTime), 2) & _
        Right("00" & Minute(dateTime), 2) & _
        Right("00" & Second(dateTime), 2)

    ToDateTimeStringMinimalSeparators = dateBody & utcOffset

End Function
...