XSLT: чтение значения в виде списка или массива

Question

У меня есть элемент xml:

<myElement>item1 item2 item3</myElement>

Я хочу использовать XSLT, чтобы преобразовать его в:

<newElement>item1</newElement>  
<newElement>item2</newElement>
<newElement>item3</newElement>  

Как выглядит xslt? Меня больше интересует, как зациклить список myElement или как сделать его списком или переменной.

Пожалуйста, сообщите.

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>


 <xsl:template match="text()[contains(., ' ')]" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:if test="string-length($pText)">
   <newElement>
    <xsl:value-of select=
     "substring-before(concat($pText,' '),' ')"/>
   </newElement>

   <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select=
     "substring-after($pText,' ')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<myElement>item1 item2 item3</myElement>

дает желаемый, правильный результат :

<newElement>item1</newElement>
<newElement>item2</newElement>
<newElement>item3</newElement>

Answer 2

В XSLT 2.0 проще:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="myElement">
   <xsl:for-each select="tokenize(., '\s+')">
     <newElement><xsl:value-of select="."/></newElement>
   </xsl:for-each>
 </xsl:template>

</xsl:stylesheet>