SQL для создания пользователей .Net Membership Provider - PullRequest
Новая
       45

SQL для создания пользователей .Net Membership Provider

5 голосов
/ 26 июня 2010

У меня есть SQL-скрипт, который создает пользователей в моей базе данных.Он использует .Net членство хранимых процедур.

На данный момент все работает нормально.

Единственная проблема заключается в том, что пароли сохранены открытым текстом. Что я должен изменить здесь, чтобы они были соленые /зашифрованный (не уверен, какой термин использовать здесь) 

GO

DECLARE @return_value int,
  @UserId uniqueidentifier


EXEC @return_value = [dbo].[aspnet_Membership_CreateUser]
  @ApplicationName = N'Theater',
  @UserName = N'sam.sosa',
  @Password = N'mypassword',
  @PasswordSalt = N'eyhKDP858wdrYHbBmFoQ6DXzFE1FB+RDP4ULrpoZXt6f',
  @Email = N'sam@Simple.com',
  @PasswordQuestion = N'Whats your favorite color',
  @PasswordAnswer = N'Fusia',
  @IsApproved = 1,
  @CurrentTimeUtc = '2010-03-03',
  @CreateDate = '2010-03-03',
  @UniqueEmail = 1,
  @PasswordFormat = 0,
  @UserId = @UserId OUTPUT

SELECT @UserId as N'@UserId'

SELECT 'Return Value' = @return_value

GO

спасибо!

1 Ответ

10 голосов
/ 02 июля 2010

Под капотом это выглядит как режим хранения хэшированных паролей, он просто вычисляет:

SHA1 (соль + пароль)

Salt хранится в кодировке Base64, поэтому его необходимо декодировать перед объединением с паролем (Unicode). Наконец, результатом является кодировка Base64 для хранения.

Следующий (ужасный) SQL выведет подходящее закодированное значение, которое можно заменить вместо «пароля-пароля», который у вас есть в данный момент. Вы также должны установить @PasswordFormat в 1, чтобы указать, что пароль хранится в хэше. 

declare @salt nvarchar(128)
declare @password varbinary(256)
declare @input varbinary(512)
declare @hash varchar(64)

-- Change these values (@salt should be Base64 encoded)
set @salt = N'eyhKDP858wdrYHbBmFoQ6DXzFE1FB+RDP4ULrpoZXt6f'
set @password = convert(varbinary(256),N'mypassword')

set @input = hashbytes('sha1',cast('' as  xml).value('xs:base64Binary(sql:variable(''@salt''))','varbinary(256)') + @password)
set @hash = cast('' as xml).value('xs:base64Binary(xs:hexBinary(sql:variable(''@input'')))','varchar(64)')

-- @hash now contains a suitable password hash
-- Now create the user using the value of @salt as the salt, and the value of @hash as the password (with the @PasswordFormat set to 1)

DECLARE @return_value int, 
  @UserId uniqueidentifier 

EXEC @return_value = [dbo].[aspnet_Membership_CreateUser] 
  @ApplicationName = N'Theater', 
  @UserName = N'sam.sosa', 
  @Password = @hash, 
  @PasswordSalt = @salt, 
  @Email = N'sam@Simple.com', 
  @PasswordQuestion = N'Whats your favorite color', 
  @PasswordAnswer = N'Fusia', 
  @IsApproved = 1, 
  @CurrentTimeUtc = '2010-03-03', 
  @CreateDate = '2010-03-03', 
  @UniqueEmail = 1, 
  @PasswordFormat = 1, 
  @UserId = @UserId OUTPUT 

SELECT @UserId as N'@UserId' 

SELECT 'Return Value' = @return_value
...