Groovy динамически вызываемый класс и метод find не работает?

Question

Я пытаюсь построить динамический запрос, похожий на:

def domain = DomainName
def ids = 1
def domainClass = "$domain" as Class
domainClass.find("from ${domain} as m where m.job = ${ids} ").id

Но это не работает.

Если я пытаюсь это сделать, то все в порядке:

def domain = DomainName
def ids = 1
DomainName.find("from ${domain} as m where m.job = ${ids} ").id

Как я могу использовать динамическое имя класса домена с find?

Answer 1

Самый простой способ - использовать метод getDomainClass:

String domainClassName = 'com.foo.bar.Person'
def ids = 1
def domainClass = grailsApplication.getDomainClass(domainClassName).clazz
domainClass.find("from $domainClassName as m where m.job = ${ids} ").id

Обратите внимание, что если вы пытаетесь получить один экземпляр по идентификатору, используйте get:

long id = 1234
def person = domainClass.get(id)

и если вы хотите получить несколько экземпляров и у вас есть список идентификаторов, вы можете использовать getAll

def ids = [1,2,3,4,5]
def people = domainClass.getAll(ids)

Также ДЕЙСТВИТЕЛЬНО плохая идея использовать GStrings со встроенными значениями свойств - Google 'SQL Injection'

Например, чтобы найти человека по имени:

String username = 'foo'
def person = domainClass.find(
    "from $domainClassName as m where m.username=:username",
    [username: username])

Answer 2

Вы должны быть в состоянии сделать это, явно используя GroovyClassLoader:

def domain = "DomainName"
def c = new GroovyClassLoader().loadClass(domain)
c.find('...').id

Answer 3

Лучший способ получить класс Domain динамически - через объект GrailsApplication.Пример:

import org.codehaus.groovy.grails.commons.ApplicationHolder

def domainName = "full.package.DomainName"
def domainGrailsClass = ApplicationHolder.application.getArtefact("Domain", domainName)
def domainClass = domainGrailsClass.getClazz()
domainClass.find("from ${domainGrailsClass.name} as m where m.job = ${ids}").id

Вы также можете использовать Class.forName() так же, как в Java.Используйте версию с тремя параметрами и передайте в загрузчик класса контекста текущего потока:

import grails.util.GrailsNameUtils

def domainName = "full.package.DomainName"
def domainClass = Class.forName(domainName, true, Thread.currentThread().getContextClassLoader())
domainClass.find("from ${GrailsNameUtils.getShortName(domainName)} as m where m.job = ${ids}").id

Загрузчики классов - уродливая тема в платформах Java и JVM.В Grails вы почти всегда хотите использовать загрузчик классов контекста потока.Но еще лучше использовать интерфейс GrailsApplication и вообще избежать этой проблемы.

Answer 4

используйте GrailsClassUtils

GrailsClassUtils.getShortName(DomainName)

, чтобы получить имя класса, так что это должно работать ... если я понял вопрос

def domainClassName = GrailsClassUtils.getShortName(DomainName)
def ids = 1
DomainName.find("from ${domainClassName} as m where m.job = ${ids} ").id