Сгруппировать не вложенную структуру XML в структуру дерева XML

Question

Мне нужно преобразовать следующий повторяющийся шаблон

<root>
    <bar>bar 1</bar>
    <baz>baz 1</baz>
    <qux>qux 1</qux>
    <bar>bar 2</bar>
    <baz>baz 2</baz>
    <qux>qux 2</qux>
</root>

В это;

<root>
    <foo>
        <bar>bar 1</bar>
        <baz>baz 1</baz>
        <qux>qux 1</qux>
    </foo>
    <foo>
        <bar>bar 2</bar>
        <baz>baz 2</baz>
        <qux>qux 2</qux>
    </foo>
</root>

Но я не хочу использовать циклические решения.

Answer 1

Много, много решений. Этот использует мелкозернистый обход:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()[1]|@*"/>
        </xsl:copy>
        <xsl:apply-templates select="following-sibling::node()[1]"/>
    </xsl:template>
    <xsl:template match="bar">
        <foo>
            <xsl:call-template name="identity"/>
        </foo>
        <xsl:apply-templates select="following-sibling::bar[1]"/>
    </xsl:template>
    <xsl:template match="qux">
        <xsl:copy>
            <xsl:apply-templates select="node()[1]|@*"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Выход:

<root>
    <foo>
        <bar>bar 1</bar>
        <baz>baz 1</baz>
        <qux>qux 1</qux>
    </foo>
    <foo>
        <bar>bar 2</bar>
        <baz>baz 2</baz>
        <qux>qux 2</qux>
    </foo>
</root>

Другое решение: стиль нажатия с ключом.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kElementByPrecedingBar" match="root/*[not(self::bar)]"
                  use="generate-id(preceding-sibling::bar[1])"/>
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="bar" mode="wrap">
        <foo>
            <xsl:apply-templates select=".|key('kElementByPrecedingBar',
                                               generate-id())"/>
        </foo>
    </xsl:template>
    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates select="bar" mode="wrap"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kFollowing" match="*[not(name()=name(/*/*[1]))]"
  use="generate-id(preceding-sibling::*[name()=name(/*/*[1])][1])"/>

 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*"/>

 <xsl:template match="/*/*[name()=name(/*/*[1])]">
  <foo>
   <xsl:apply-templates select=".|key('kFollowing', generate-id())" mode="copy"/>
  </foo>
 </xsl:template>

 <xsl:template match="*" mode="copy">
  <xsl:call-template name="identity"/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<root>
    <bar>bar 1</bar>
    <baz>baz 1</baz>
    <qux>qux 1</qux>
    <bar>bar 2</bar>
    <baz>baz 2</baz>
    <qux>qux 2</qux>
</root>

дает желаемый, правильный результат :

<root>
    <foo>
        <bar>bar 1</bar>
        <baz>baz 1</baz>
        <qux>qux 1</qux>
    </foo>
    <foo>
        <bar>bar 2</bar>
        <baz>baz 2</baz>
        <qux>qux 2</qux>
    </foo>
</root>

Примечание :

1. Преобразованию не нужно знать и жестко кодировать любое имя элемента - оно просто использует тот факт, что последовательность имен элементов повторяется.

2. Использование клавиш для поиска всех членов группы.

3. Использование режимов для обработки одних и тех же узлов несколькими способами.