F # Сериализация типов записей

Question

Я знаю, как сериализовать в F #, используя изменяемые объекты, но есть ли способ сериализации / десериализации, используя типы записей, используя XmlSerializer или DataContractSerializer?Похоже, что есть способ сделать это для различенного объединения, используя атрибут KnownType, но я ищу способ использовать неизменяемые записи без конструктора по умолчанию ...

Answer 1

Начиная с F # 3.0, сериализация типов записей теперь поддерживается с применением CliMutableAttribute к типу.Пример:

[<CLIMutable>] 
type MyRecord = { Name : string; Age : int }

Этот пример взят из http://blogs.msdn.com/b/fsharpteam/archive/2012/07/19/more-about-fsharp-3.0-language-features.aspx,, который включает обсуждение этой функции и трех других новых функций в F # 3.0: строки в тройных кавычках, автоматические свойства и предупреждения о неиспользуемых переменных.

Answer 2

Пример кода для чтения данных из Freebase Джомо Фишером использует DataContractJsonSerializer для загрузки данных в неизменяемые записи F #.Объявление записи, которую он использует, выглядит следующим образом:

[<DataContract>]
type Result<'TResult> = { // '
    [<field: DataMember(Name="code") >]
    Code:string
    [<field: DataMember(Name="result") >]
    Result:'TResult // '
    [<field: DataMember(Name="message") >]
    Message:string }

Ключевым моментом здесь является то, что атрибут DataMember присоединен к базовому полю, которое фактически используется для хранения данных, а не ксвойство только для чтения, которое генерирует компилятор F # (с использованием модификатора field: в атрибуте).

Я не уверен на 100%, будет ли это работать с другими типами сериализации (возможно, нет),но это может быть полезным указателем для начала ...

РЕДАКТИРОВАТЬ Я не уверен, что я что-то здесь упускаю, но следующий базовый пример отлично работает для меня:

module Demo

#r "System.Runtime.Serialization.dll"

open System.IO  
open System.Text  
open System.Xml 
open System.Runtime.Serialization

type Test = 
  { Result : string[]
    Title : string }

do
  let sb = new StringBuilder()
  let value = { Result = [| "Hello"; "World" |]; Title = "Hacking" }
  let xmlSerializer = DataContractSerializer(typeof<Test>); 
  xmlSerializer.WriteObject(new XmlTextWriter(new StringWriter(sb)), value)
  let sr = sb.ToString()
  printfn "%A" sr

  let xmlSerializer = DataContractSerializer(typeof<Test>); 
  let reader = new XmlTextReader(new StringReader(sr))
  let obj = xmlSerializer.ReadObject(reader) :?> Test
  printfn "Reading: %A" obj

РЕДАКТИРОВАТЬ 2 Если вы хотите создать более чистый XML, вы можете добавить такие атрибуты, как это:

[<XmlRoot("test")>] 
type Test = 
  { [<XmlArrayAttribute("results")>] 
    [<XmlArrayItem(typeof<string>, ElementName = "string")>] 
    Result : string[]
    [<XmlArrayAttribute("title")>] 
    Title : string }

Answer 3

Он не использует XmlSerializer или DataContractSerializer, но Json.NET 6.0 включает хорошую поддержку F #.

Это выглядит так:

type TestTarget = 
    { a: string
      b: int }

[<TestFixture>]
type JsonTests() = 
    [<Test>]
    member x.``can serialize``() = 
        let objectUnderTest = { TestTarget.a = "isa"; b = 9 }
        let jsonResult: string = Newtonsoft.Json.JsonConvert.SerializeObject(objectUnderTest)
        printfn "json is:\n%s" jsonResult
        let xmlResult = Newtonsoft.Json.JsonConvert.DeserializeXmlNode(jsonResult, "root")
        printfn "xml is:\n%s" (xmlResult.OuterXml)

        let jsonRoundtrip = Newtonsoft.Json.JsonConvert.DeserializeObject<TestTarget>(jsonResult)
        printfn "json roundtrip: %A" jsonRoundtrip

        let xmlAsJson = Newtonsoft.Json.JsonConvert.SerializeXmlNode(xmlResult, Newtonsoft.Json.Formatting.Indented, true)
        printfn "object -> json -> xml -> json:\n%A" xmlAsJson
        let xmlRoundtrip = Newtonsoft.Json.JsonConvert.DeserializeObject<TestTarget>(xmlAsJson)
        printfn "xml roundtrip:\n%A" xmlRoundtrip

        Assert.That(true, Is.False)
        ()

json is:
{"a":"isa","b":9}
xml is:
<root><a>isa</a><b>9</b></root>
json roundtrip: {a = "isa";
 b = 9;}
object -> json -> xml -> json:
"{
  "a": "isa",
  "b": "9"
}"
xml roundtrip:
{a = "isa";
 b = 9;}

Answer 4

Вы можете использовать эту серию аннотаций о свойствах классов для форматирования XML:

[XmlRoot("root")]
[XmlElement("some-element")]
[XmlAttribute("some-attribute")]
[XmlArrayAttribute("collections")]
[XmlArrayItem(typeof(SomeClass), ElementName = "item")]

Я использую атрибуты в моих классах c #, но десериализовываю в F # (классы c # являются ссылочной lib).

в ф #:

use file = new FileStream(filePath, FileMode.Open)
let serializer= XmlSerializer(typeof<SomeClass>)
let docs = serializer.Deserialize file :?> SomeClass