Как я могу добавить часть в XML с помощью xslt и xsltproc?

Question

У меня есть xml-файл:

<?xml version="1.0" encoding="iso-8859-1"?>
<Configuration>
  <Parameter2>
  </Parameter2>
</Configuration>

, и я хочу добавить следующую часть в мой xml-файл между <Configuration> и <Parameter2> частями.

<Parameter1>
   <send>0</send>
   <interval>0</interval>
   <speed>200</speed>
</Parameter1> 

Answer 1

Этот XSLT вставляет указанное содержимое как дочерний элемент элемента Configuration перед Parameter2.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" />

    <xsl:template match="Configuration">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <!--Check for the presence of Parameter1 in the config file to ensure that it does not get re-inserted if this XSLT is executed against the output-->
            <xsl:if test="not(Parameter1)">
                <Parameter1>
                    <send>0</send>
                    <interval>0</interval>
                    <speed>200</speed>
                </Parameter1>
            </xsl:if>
            <!--apply templates to children, which will copy forward Parameter2 (and Parameter1, if it already exists)-->
            <xsl:apply-templates select="node()" />
        </xsl:copy>
    </xsl:template>

    <!--standard identity template, which copies all content forward-->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Answer 2

Укороченное решение. Эта таблица стилей:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="@*|node()" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="Configuration/*[1]">
        <Parameter1>
            <send>0</send>
            <interval>0</interval>
            <speed>200</speed>
        </Parameter1>
        <xsl:call-template name="identity" />
    </xsl:template>
</xsl:stylesheet>

Выход:

<Configuration>
    <Parameter1>
        <send>0</send>
        <interval>0</interval>
        <speed>200</speed>
    </Parameter1>
    <Parameter2></Parameter2>
</Configuration>

Примечание : Если вы хотите добавить Parameter1 только в том случае, если такого элемента нет ни в одной позиции, вы должны изменить шаблон для: Configuration/*[1][not(/Configuration/Parameter1)]