XSLT не работает, когда я включаю xmlns = "http://www.sitemaps.org/schemas/sitemap/0.9" - PullRequest
Новая
       14

XSLT не работает, когда я включаю xmlns = "http://www.sitemaps.org/schemas/sitemap/0.9"

12 голосов
/ 01 октября 2010

Моя карта сайта Google хорошо отображается через XSLT без xmlns = "http://www.sitemaps.org/schemas/sitemap/0.9" в элементе , однако при включении мое выражение foreach не работает и ничего не отображается в шаблоне. Мой код приведен ниже. Спасибо за ваша помощь.

XML 

<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">
<url>
<loc>{site_url}</loc>
<lastmod>{current_time format="%Y-%m-%d"}</lastmod>
<changefreq>monthly</changefreq>
<priority>0.5</priority>
</url>
</urlset>

1010 * XSL * 

<xsl:template match="/">
<html>
<body>
<h2>Sitemap</h2>
<table border="1">
<tr bgcolor="#9acd32">
  <th>Location</th>
  <th>Last Modified</th>
  <th>Update Frequency</th>
  <th>Priority</th>
</tr>
<xsl:for-each select="urlset/url">
<tr>
  <td><xsl:value-of select="loc"/></td>
  <td><xsl:value-of select="lastmod"/></td>
  <td><xsl:value-of select="changefreq"/></td>
  <td><xsl:value-of select="priority"/></td>
</tr>
</xsl:for-each>
</table>
</body>
</html>

Ответы [ 2 ]

17 голосов
/ 01 октября 2010

Моя карта сайта Google хорошо отображается XSLT нормально без xmlns="http://www.sitemaps.org/schemas/sitemap/0.9" в элементе <urlset>, однако когда включено, мое foreach утверждение не работает и ничего не делает в шаблон

Это FAQ .

XPath рассматривает любое имя без префикса как принадлежащее «без пространства имен». Однако элементы в предоставленном документе принадлежат пространству имен "http://www.sitemaps.org/schemas/sitemap/0.9", а не "no namespace".

Следовательно, следующее выражение XPath вообще не выбирает ни одного узла: 

urlset/url

Решение

Определите пространство имен "http://www.sitemaps.org/schemas/sitemap/0.9" в таблице стилей XSLT и свяжите с ним префикс. Затем используйте этот префикс со всеми именами, участвующими в любом выражении XPath. 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:s="http://www.sitemaps.org/schemas/sitemap/0.9"
 exclude-result-prefixes="s"
>

 <xsl:template match="/">
  <html>
    <body>
      <h2>Sitemap</h2>
      <table border="1">
        <tr bgcolor="#9acd32">
          <th>Location</th>
          <th>Last Modified</th>
          <th>Update Frequency</th>
          <th>Priority</th>
        </tr>
        <xsl:for-each select="s:urlset/s:url">
          <tr>
            <td><xsl:value-of select="s:loc"/></td>
            <td><xsl:value-of select="s:lastmod"/></td>
            <td><xsl:value-of select="s:changefreq"/></td>
            <td><xsl:value-of select="s:priority"/></td>
          </tr>
        </xsl:for-each>
      </table>
    </body>
  </html>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML : 

<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">
    <url>
        <loc>{site_url}</loc>
        <lastmod>{current_time format="%Y-%m-%d"}</lastmod>
        <changefreq>monthly</changefreq>
        <priority>0.5</priority>
    </url>
</urlset>

правильно выдает следующий результат : 

<html>
   <body>
      <h2>Sitemap</h2>
      <table border="1">
         <tr bgcolor="#9acd32">
            <th>Location</th>
            <th>Last Modified</th>
            <th>Update Frequency</th>
            <th>Priority</th>
         </tr>
         <tr>
            <td>{site_url}</td>
            <td>{current_time format="%Y-%m-%d"}</td>
            <td>monthly</td>
            <td>0.5</td>
         </tr>
      </table>
   </body>
</html>
3 голосов
/ 01 октября 2010

xpath потребуется пространство имен в качестве префикса, например, 

{http://www.sitemaps.org/schemas/sitemap/0.9}urlset

если это был xmlns: x = "http://www.sitemaps.org/schemas/sitemap/0.9", вы можете использовать 

x:urlset

похоже, эта страница поможет http://msdn.microsoft.com/en-us/library/ms950779.aspx

РЕДАКТИРОВАТЬ: я собирался опубликовать это и последует пример того, как использовать xsl для определения префикса, но Dimitre уже есть.

...