Опоздал к игре здесь (mwolfe02 ответил на это год назад!), Но проблема все еще актуальна, есть альтернативные подходы, которые стоит изучить, и StackOverflow - место, где их можно найти: так вот мой собственный ответ ...
Несколько лет назад VBA.IsDate () подвела меня к этой проблеме и написала расширенную функцию, которая покрывает случаи, которые VBA.IsDate () плохо обрабатывает. Хуже всего то, что числа с плавающей запятой и целые числа возвращают FALSE из IsDate, хотя сериалы даты часто передаются как Double (для DateTime) и Long Integer (для дат).
Обратите внимание: вашей реализации может не потребоваться возможность проверять варианты массивов. Если нет, не стесняйтесь вырезать код в блоке с отступом, который следует за Else ' Comment this out if you don't need to check array variants. Однако вы должны знать, что некоторые сторонние системы (включая клиентов рыночных данных в реальном времени) возвращают свои данные в массивах, даже в отдельных точках данных.
Больше информации в комментариях к коду.
Вот код:
Public Function IsDateEx(TestDate As Variant, Optional LimitPastDays As Long = 7305, Optional LimitFutureDays As Long = 7305, Optional FirstColumnOnly As Boolean = False) As Boolean
'Attribute IsDateEx.VB_Description = "Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.
'Attribute IsDateEx.VB_ProcData.VB_Invoke_Func = "w\n9"
Application.Volatile False
On Error Resume Next
' Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.
' This extends VBA.IsDate(), which returns FALSE for floating-point numbers and integers
' even though the VBA Serial Date is a Double. IsDateEx() returns TRUE for variants that
' can be parsed into string dates, and numeric values with equivalent date serials. All
' values must still be ±20 years from SysDate. Note: locale and language settings affect
' the validity of day- and month names; and partial date strings (eg: '01 January') will
' be parsed with the missing components filled-in with system defaults.
' Optional parameters LimitPastDays/LimitFutureDays vary the default ± 20 years boundary
' Note that an array variant is an acceptable input parameter: IsDateEx will return TRUE
' if all the values in the array are valid dates: set FirstColumnOnly:=TRUE if you only
' need to check the leftmost column of a 2-dimensional array.
' * THIS CODE IS IN THE PUBLIC DOMAIN
' *
' * Author: Nigel Heffernan, May 2005
' * http://excellerando.blogspot.com/
' *
' *
' * *********************************
Dim i As Long
Dim j As Long
Dim k As Long
Dim jStart As Long
Dim jEnd As Long
Dim dateFirst As Date
Dim dateLast As Date
Dim varDate As Variant
dateFirst = VBA.Date - LimitPastDays
dateLast = VBA.Date + LimitFutureDays
IsDateEx = False
If TypeOf TestDate Is Excel.Range Then
TestDate = TestDate.Value2
End If
If VarType(TestDate) < vbArray Then
If IsDate(TestDate) Or IsNumeric(TestDate) Then
If (dateLast > TestDate) And (TestDate > dateFirst) Then
IsDateEx = True
End If
End If
Else ' Comment this out if you don't need to check array variants
k = ArrayDimensions(TestDate)
Select Case k
Case 1
IsDateEx = True
For i = LBound(TestDate) To UBound(TestDate)
If IsDate(TestDate(i)) Or IsNumeric(TestDate(i)) Then
If Not ((dateLast > CVDate(TestDate(i))) And (CVDate(TestDate(i)) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next i
Case 2
IsDateEx = True
jStart = LBound(TestDate, 2)
If FirstColumnOnly Then
jEnd = LBound(TestDate, 2)
Else
jEnd = UBound(TestDate, 2)
End If
For i = LBound(TestDate, 1) To UBound(TestDate, 1)
For j = jStart To jEnd
If IsDate(TestDate(i, j)) Or IsNumeric(TestDate(i, j)) Then
If Not ((dateLast > CVDate(TestDate(i, j))) And (CVDate(TestDate(i, j)) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next j
Next i
Case Is > 2
' Warning: For... Each enumerations are SLOW
For Each varDate In TestDate
If IsDate(varDate) Or IsNumeric(varDate) Then
If Not ((dateLast > CVDate(varDate)) And (CVDate(varDate) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next varDate
End Select
End If
End Function
Совет для людей, все еще использующих Excel 2003:
Если вы (или ваши пользователи) собираетесь вызывать IsDateEx () с рабочего листа, поместите эти две строки, сразу под заголовком функции, с помощью текстового редактора в экспортированном файле .bas и повторно импортируйте файл потому что атрибуты VB полезны, но они не доступны для редактора кода в Excel VBA IDE :
Attribute IsDateEx.VB_Description = "Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.\r\nChange the defaulte default ± 20 years boundaries by setting values for LimitPastDays and LimitFutureDays\r\nIf you are checking an array of dates, ALL the values will be tested: set FirstColumnOnly TRUE to check the leftmost column only."
Это все одна строка: следите за разрывом строк, вставленным браузером! ... И эта строка, которая помещает isDateEX в мастер функций в категории «Информация», рядом с ISNUMBER (), ISERR (), ISTEXT () и т. Д .:
Attribute IsDateEx.VB_ProcData.VB_Invoke_Func = "w\n9"
Используйте «w \ n2», если вы предпочитаете видеть его в функциях «Дата и время»: превосходно теряете его во множестве функций «Использовано определено» из вашего собственного кода и всех сторонних надстроек разработано людьми, которые не делают вполне достаточно, чтобы помочь случайным пользователям.
Понятия не имею, работает ли это все еще в Office 2010.
Также вам может понадобиться источник для ArrayDimensions:
Это объявление API требуется в заголовке модуля:
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, _
Source As Any, _
ByVal Length As Long)
… А вот и сама функция:
Private Function ArrayDimensions(arr As Variant) As Integer
'-----------------------------------------------------------------
' will return:
' -1 if not an array
' 0 if an un-dimmed array
' 1 or more indicating the number of dimensions of a dimmed array
'-----------------------------------------------------------------
' Retrieved from Chris Rae's VBA Code Archive - http://chrisrae.com/vba
' Code written by Chris Rae, 25/5/00
' Originally published by R. B. Smissaert.
' Additional credits to Bob Phillips, Rick Rothstein, and Thomas Eyde on VB2TheMax
Dim ptr As Long
Dim vType As Integer
Const VT_BYREF = &H4000&
'get the real VarType of the argument
'this is similar to VarType(), but returns also the VT_BYREF bit
CopyMemory vType, arr, 2
'exit if not an array
If (vType And vbArray) = 0 Then
ArrayDimensions = -1
Exit Function
End If
'get the address of the SAFEARRAY descriptor
'this is stored in the second half of the
'Variant parameter that has received the array
CopyMemory ptr, ByVal VarPtr(arr) + 8, 4
'see whether the routine was passed a Variant
'that contains an array, rather than directly an array
'in the former case ptr already points to the SA structure.
'Thanks to Monte Hansen for this fix
If (vType And VT_BYREF) Then
' ptr is a pointer to a pointer
CopyMemory ptr, ByVal ptr, 4
End If
'get the address of the SAFEARRAY structure
'this is stored in the descriptor
'get the first word of the SAFEARRAY structure
'which holds the number of dimensions
'...but first check that saAddr is non-zero, otherwise
'this routine bombs when the array is uninitialized
If ptr Then
CopyMemory ArrayDimensions, ByVal ptr, 2
End If
End Function
Пожалуйста, сохраняйте подтверждения в своем исходном коде: по мере того, как вы будете продвигаться по карьерной лестнице в качестве разработчика, вы по достоинству оцените ваш собственный вклад в признание.
Также: я бы посоветовал вам сохранить это заявление в секрете. Если вам нужно сделать его общедоступным Sub в другом модуле, вставьте оператор Option Private Module в заголовок модуля. Вы действительно не хотите, чтобы ваши пользователи вызывали какую-либо функцию с помощью CopyMemoryoperations и арифметики указателей.