SQL Server 2005 - закрытие спящих подключений - PullRequest
Новая
       14

SQL Server 2005 - закрытие спящих подключений

2 голосов
/ 15 декабря 2008

У меня на моем Dev-сервере есть приложение с множеством открытых соединений (они должны быть там, но для их открытия использовался какой-то плохой слой данных, который забыл закрыть их) Я просто хочу, чтобы они были закрыты, чтобы другие приложения работали на сервере. Как я могу принудительно закрыть все соединения?

Ответы [ 4 ]

5 голосов
/ 15 декабря 2008

Используйте следующий скрипт для уничтожения неактивных сеансов с определенного хоста / логина. Вы можете использовать его по расписанию, конечно же, вашим приоритетом должно быть исправление уровня приложения. 

SET NOCOUNT ON;

DECLARE @host VARCHAR(50), @login NVARCHAR(128);

SET @host = 'fooHost'; --NULL to kill sessions from all hosts.
SET @login = 'fooLogin';

DECLARE @cmd NVARCHAR(255);
DECLARE @possition INT, @total INT, @selSpid SMALLINT;
DECLARE @spidInfo TABLE
(
    [id] INT IDENTITY(1,1),
    spid SMALLINT,
    loginame NVARCHAR(128)
);

INSERT @spidInfo(spid, loginame)
SELECT session_id, login_name 
FROM sys.dm_exec_sessions
WHERE is_user_process = 1 AND [status] = 'sleeping' AND 
    login_name = @login AND [host_name] = COALESCE(@host, [host_name]);

SELECT @total = @@IDENTITY, @selSpid = 0, @possition = 0;

WHILE @possition < @total
    BEGIN
        SELECT TOP 1 @selSpid = spid, @possition = [id]
        FROM @spidInfo
        WHERE [ID] > @possition

        SET @cmd = N'KILL ' + CAST(@selSpid AS NVARCHAR(10));
        EXEC sp_executesql @cmd;
        PRINT 'SessionId = ' + CAST(@selSpid AS NVARCHAR(10)) + '[' + @login + 
            '] killed by ' + system_user + ' at ' + CAST(GETDATE() AS VARCHAR(50));
    END;

IF (@total = 0)
    PRINT 'No sessions owned by user ' + '[' + @login + ']';
3 голосов
/ 15 декабря 2008

Используйте столбец last_batch из sysprocesses, чтобы выяснить, действительно ли он активен или нет. SPID> 50 (или>> = 50?), Чтобы избежать уничтожения системных SPID.

Сравните это с желаемым временем сна и убийством.

Вам придется пройти через. 

DECLARE @kill_id smallint 
DECLARE spid_cursor CURSOR FOR
select spid from sysprocesses 
where dbid = > 4 and last_batch < dateadd(hour, -24, getdate()) and spid >= 50

OPEN spid_cursor

FETCH NEXT FROM spid_cursor INTO @kill_id

WHILE (@@FETCH_STATUS = 0)
BEGIN
-- Kill the current spid here
-- KILL @kill_id <---This line will not work

-- Get the next cursor row
FETCH NEXT FROM spid_cursor INTO @kill_id
END 

CLOSE spid_cursor

DEALLOCATE spid_cursor
3 голосов
/ 15 декабря 2008

Кроме уничтожения ваших соединений вручную, вы можете

  • Утилизируйте соединения. То есть как-то получить объекты Connection и вызвать для них .Close и .Dispose (). Использование «using» было бы идеальным, поскольку оно автоматически вызывает .Dispose () для вас.
  • Перезапустите пул приложений.
2 голосов
/ 21 марта 2009

Сначала запустите эту программу, чтобы найти базу данных нарушителя ..... 

SELECT DB_NAME(dbid) as 'Database Name', 
COUNT(dbid) as 'Total Connections' 
FROM master.dbo.sysprocesses WITH (nolock)
WHERE dbid > 0
GROUP BY dbid
SELECT @@MAX_CONNECTIONS AS 'Max Allowed Connections'

Затем запустите эту команду, чтобы уничтожить соединения с нужной БД 

USE master
go

DECLARE @dbname sysname

SET @dbname = 'Events'

DECLARE @spid int
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname)
WHILE @spid IS NOT NULL
BEGIN
EXECUTE ('KILL ' + @spid)
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname) AND spid > @spid
END
...