Ссылка на ярлык в Listview (Delphi) - PullRequest
Новая
       31

Ссылка на ярлык в Listview (Delphi)

0 голосов
/ 29 января 2011

как мне получить просмотр списка, в котором его элементы содержат ссылки (направьте нас на html-страницы)?

Спасибо

Ответы [ 2 ]

6 голосов
/ 29 января 2011

Либо используйте просмотр списка или сетку, которая поддерживает это готовое ( программное обеспечение tms , например, имеет компоненты, которые поддерживают "мини" html), либо со стандартным TListView сделайте что-то вроде: 

type
  TLinkItem = class(TObject)
  private
    FCaption: string;
    FURL: string;
  public
    constructor Create(const aCaption, aURL: string);
    property Caption: string read FCaption write FCaption;
    property URL: string read FURL write FURL;
  end;

constructor TLinkItem.Create(const aCaption, aURL: string);
begin
  FCaption := aCaption;
  FURL := aURL;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  Item: TListItem;
  i: Integer;
begin
  FLinkItems := TObjectList.Create({AOwnsObjects=}True);
  FLinkItems.Add(TLinkItem.Create('StackOverflow', 'http://www.stackoverflow.com'));
  FLinkItems.Add(TLinkItem.Create('BJM Software', 'http://www.bjmsoftware.com'));

  for i := 0 to FLinkItems.Count - 1 do
  begin
    Item := ListView1.Items.Add;
    Item.Caption := TLinkItem(FLinkItems[i]).Caption;
    Item.Data := Pointer(FLinkItems[i]);
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FreeAndNil(FLinkItems);
end;

procedure TForm1.ListView1Click(Sender: TObject);
var
  LinkItem: TLinkItem;
  URL: string;
begin
  LinkItem := TLinkItem(ListView1.Items[ListView1.ItemIndex].Data);
  URL := LinkItem.URL;
  ShellExecute(Handle, 'open', PChar(URL), nil, nil, SW_SHOW);
end;

Вам решать, как вы хотите, чтобы ваш цвет заголовков ссылок в вашем ListView. Если бы вы придерживались давних интернет-стандартов, вы бы сделали их голубыми и подчеркнутыми.

2 голосов
/ 30 января 2011

Хм, да, легко пойти дальше и вызвать браузер по умолчанию с Delphi. Вот базовый пример с проверкой (так что вы можете иметь значения не-URL в вашем списке): 

uses ShLwApi, ShellApi;

procedure TForm1.ListView1DblClick(Sender: TObject);
begin
  if PathIsURL(PChar(ListView1.Selected.Caption)) then
  begin
    ShellExecute(self.WindowHandle, 'open', PChar(ListView1.Selected.Caption),
      nil, nil, SW_SHOWNORMAL);
  end;
end;
...