Построение вложенной иерархии идентификаторов с использованием XSLT

Question

Продолжая мой предыдущий вопрос .

XML

<albums>
    <album title="new_zealand">
        <album title="auckland">
            <image title="mt_eden_railroad_station"/>
        </album>
    </album>
</albums>

Ожидаемый результат

<div>
    <a href="#new_zealand">new_zealand</a>
</div>

<div id="new_zealand">
    <a href="#new_zealand/auckland">auckland</a>
</div>

<div id="new_zealand/auckland">
    <img id="new_zealand/auckland/mt_eden_railroad_station"/>
</div>

XSL, это не работает

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html"/>

    <xsl:template match="/">
        <xsl:apply-templates select="/albums | //album"/>
    </xsl:template>

    <xsl:template match="albums | album">
        <div>
            <xsl:attribute name="id">
                <!--  I need to insert '/' between all parents titles and concat them. -->
            </xsl:attribute>
            <xsl:apply-templates select="album/@title | image"/>
        </div>
    </xsl:template>

    <xsl:template match="album/@title">
        <a href="{concat('#', .)}">
            <xsl:value-of select="."/>
        </a>
    </xsl:template>

    <xsl:template match="image">
        <img id="{@title}"/>
    </xsl:template>

</xsl:stylesheet>

Answer 1

Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="albums">
        <div>
            <xsl:apply-templates mode="output"/>
        </div>
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="album">
        <xsl:param name="pPath"/>
        <xsl:variable name="vNextPath" select="concat($pPath,@title,'/')"/>
        <div id="{$pPath}{@title}">
            <xsl:apply-templates mode="output">
                <xsl:with-param name="pPath" select="$vNextPath"/>
            </xsl:apply-templates>
        </div>
        <xsl:apply-templates>
            <xsl:with-param name="pPath" select="$vNextPath"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="image" mode="output">
        <xsl:param name="pPath"/>
        <img id="{$pPath}{@title}"/>
    </xsl:template>
    <xsl:template match="album" mode="output">
        <xsl:param name="pPath"/>
        <a href="#{$pPath}{@title}">
            <xsl:value-of select="@title"/>
        </a>
    </xsl:template>
</xsl:stylesheet>

Вывод:

<div>
   <a href="#new_zealand">new_zealand</a>
</div>
<div id="new_zealand">
   <a href="#new_zealand/auckland">auckland</a>
</div>
<div id="new_zealand/auckland">
   <img id="new_zealand/auckland/mt_eden_railroad_station" />
</div>

Редактировать : просто для удовольствия, другая таблица стилей с той же логикой для albums и album

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="albums|album">
        <xsl:param name="pPath"/>
        <xsl:variable name="vPath" select="concat($pPath,@title)"/>
        <xsl:variable name="vNextPath"
             select="concat($vPath,substring('/',1 div boolean($vPath)))"/>
        <div>
            <xsl:if test="$vPath">
                <xsl:attribute name="id">
                    <xsl:value-of select="$vPath"/>
                </xsl:attribute>
            </xsl:if>
            <xsl:apply-templates mode="output">
                <xsl:with-param name="pPath" select="$vNextPath"/>
            </xsl:apply-templates>
        </div>
        <xsl:apply-templates>
            <xsl:with-param name="pPath" select="$vNextPath"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="image" mode="output">
        <xsl:param name="pPath"/>
        <img id="{$pPath}{@title}"/>
    </xsl:template>
    <xsl:template match="album" mode="output">
        <xsl:param name="pPath"/>
        <a href="#{$pPath}{@title}">
            <xsl:value-of select="@title"/>
        </a>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Это преобразование :

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="album">
  <xsl:param name="pLastPath"/>

  <xsl:variable name="vPath">
   <xsl:for-each select="ancestor-or-self::album">
     <xsl:value-of select="@title"/>
     <xsl:if test="not(position()=last())">/</xsl:if>
   </xsl:for-each>
  </xsl:variable>

  <div>
   <xsl:if test="$pLastPath">
    <xsl:attribute name="id"><xsl:value-of select="$pLastPath"/></xsl:attribute>
   </xsl:if>
    <a href="#{$vPath}"><xsl:value-of select="@title"/></a>
  </div>
     <xsl:apply-templates select="node()">
       <xsl:with-param name="pLastPath" select="$vPath"/>
     </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="image">
  <xsl:param name="pLastPath"/>
   <div id="{$pLastPath}">
     <img id="{$pLastPath}/{@title}"/>
   </div>
     <xsl:apply-templates select="node()">
       <xsl:with-param name="pLastPath" select="$pLastPath"/>
     </xsl:apply-templates>
 </xsl:template>
</xsl:stylesheet>

применительно к предоставленному документу XML :

<albums>
    <album title="new_zealand">
        <album title="auckland">
            <image title="mt_eden_railroad_station"/>
        </album>
    </album>
</albums>

дает желаемый, правильный результат :

<div>
   <a href="#new_zealand">new_zealand</a>
</div>
<div id="new_zealand">
   <a href="#new_zealand/auckland">auckland</a>
</div>
<div id="new_zealand/auckland">
   <img id="new_zealand/auckland/mt_eden_railroad_station"/>
</div>

ОБНОВЛЕНИЕ : @Tomalak выразил опасение, что косые черты недопустимы в значениях атрибутов HTML id.

Пожалуйста, не стесняйтесь заменять символ "/" в этом решении любым допустимым символом (например, "_"), который вы хотите.