Отображение заставки в Delphi, когда основной поток занят

Question

Я хотел бы отобразить заставку во время загрузки приложения. Однако некоторые сторонние компоненты блокируют основной поток во время инициализации на несколько секунд, что приводит к тому, что все формы не обновляются. Возможно ли иметь заставку с собственным потоком, чтобы он также обновлялся, когда основной поток занят?

Приложение - win32 и Delphi версии 2007.

Редактировать: я пытаюсь избежать эффекта «неиспользованный экран-заставка», который происходит, если некоторые другие окна (из других приложений) находятся в верхней части экрана-заставки, например, alt-tabbing для другого приложения и обратно.

Answer 1

Вы можете запустить заставку в другом потоке, но тогда вам нужно будет использовать необработанные вызовы Windows API или стороннюю библиотеку (например, Библиотека ключевых объектов ), которая реализует VCL-подобные классы. Однако не открывайте содержимое VCL из потока-заставки.

Если вы идете по этому пути (что я не думаю, что вы должны, так как это много работы для получения небольшой выгоды), обязательно соблюдайте правила доступа к API Windows из нескольких потоков. Google, например, для «темы пользовательского интерфейса» для получения дополнительной информации.

Edit:

Я не знал об этом раньше, но на самом деле есть компонент, реализующий Threaded Splashscreen для Delphi в CodeCentral. Используя этот компонент, может быть (не пробовал) на самом деле легко иметь заставку в другом потоке, но предупреждение о доступе VCL из вторичных потоков остается.

Answer 2

На самом деле способ WinApi довольно прост, если вы используете диалоговые ресурсы. Проверьте это (работает даже на D7 и XP):

type
  TDlgThread = class(TThread)
  private
    FDlgWnd: HWND;
    FCaption: string;
  protected
    procedure Execute; override;
    procedure ShowSplash;
  public
    constructor Create(const Caption: string);
  end;

{ TDlgThread }

// Create thread for splash dialog with custom Caption and show the dialog
constructor TDlgThread.Create(const Caption: string);
begin
  FCaption := Caption;
  inherited Create(False);
  FreeOnTerminate := True;
end;

procedure TDlgThread.Execute;
var Msg: TMsg;
begin
  ShowSplash;
  // Process window messages until the thread is finished
  while not Terminated and GetMessage(Msg, 0, 0, 0) do
  begin
    TranslateMessage(Msg);
    DispatchMessage(Msg);
  end;
  EndDialog(FDlgWnd, 0);
end;

procedure TDlgThread.ShowSplash;
const
  PBM_SETMARQUEE = WM_USER + 10;
  {$I 'Dlg.inc'}
begin
  FDlgWnd := CreateDialogParam(HInstance, MakeIntResource(IDD_WAITDLG), 0, nil, 0);
  if FDlgWnd = 0 then Exit;
  SetDlgItemText(FDlgWnd, IDC_LABEL, PChar(FCaption));           // set caption
  SendDlgItemMessage(FDlgWnd, IDC_PGB, PBM_SETMARQUEE, 1, 100);  // start marquee
end;

procedure TForm1.Button3Click(Sender: TObject);
var th: TDlgThread;
begin
  th := TDlgThread.Create('Connecting to DB...');
  Sleep(3000); // blocking wait
  th.Terminate;
end;

Конечно, вы должны подготовить ресурс диалога (Dlg.rc) и добавить его в свой проект:

#define IDD_WAITDLG 1000
#define IDC_PGB 1002
#define IDC_LABEL 1003

#define PBS_SMOOTH  0x00000001
#define PBS_MARQUEE 0x00000008

IDD_WAITDLG DIALOGEX 10,10,162,33
STYLE WS_POPUP|WS_VISIBLE|WS_DLGFRAME|DS_CENTER
EXSTYLE WS_EX_TOPMOST
BEGIN
  CONTROL "",IDC_PGB,"msctls_progress32",WS_CHILDWINDOW|WS_VISIBLE|PBS_SMOOTH|PBS_MARQUEE,9,15,144,15
  CONTROL "",IDC_LABEL,"Static",WS_CHILDWINDOW|WS_VISIBLE,9,3,144,9
END

Обратите внимание, что PBS_* определяет. Мне пришлось добавить их, потому что Delphi 7 ничего не знает об этих константах. И определение констант (Dlg.inc)

const IDD_WAITDLG = 1000;
const IDC_PGB = 1002;
const IDC_LABEL = 1003;

(я использую редактор ресурсов RadAsm, который генерирует включаемый файл автоматически).

Что мы получаем под XP

Что лучше по сравнению с трюками VCL (упорядочение создания форм и т. П.), Так это то, что вы можете использовать его несколько раз, когда вашему приложению требуется время для размышлений.

Answer 3

Сначала создайте заставку в DPR, но не используйте для нее метод Application.CreateForm . Вот простой код:

begin
  Application.Initialize;
  SplashForm := TSplashForm.Create(nil);
  try
    SplashForm.FormStyle := fsStayOnTop;
    SplashForm.Show;
    Application.ProcessMessages;
    Application.CreateForm(TForm14, Form14);
    // Other Form Creation here . . . .
    Application.Run;
  finally
    if assigned(SplashForm) then
      SplashForm.Release;
  end;
end.

Затем поместите следующий код в обработчик события Show (или позже - после завершения инициализации) для вашего MainFrom (в данном случае Form14):

SplashForm.Close;
SplashForm.Release;
SplashForm := nil;

(Вы вызываете Release в форме вместо Free, и вы присваиваете ей nil, чтобы DRP больше не вызывал release. Выпуск в DRP на тот случай, если ваша основная форма не может быть создана.)

Поскольку ваша форма-заставка FormStyle: = fsStayOnTop , не должно быть проблемой, если она не получает сообщения рисования, когда блокируется ваш основной поток. Затем, когда основной поток разблокируется, вы отправляете ему сообщение об обновлении (для изменения индикатора выполнения и т. Д.). Хотя я согласен с Gamecat, что вы можете обратиться к сторонним поставщикам компонентов и попросить их прекратить блокировать основной поток на вас.

В качестве альтернативы вы можете создать сторонние компоненты в отдельном потоке (при условии, что они не визуальные, так как это будет немного сложнее).

Это будет работать с Application.MainFormOnTaskBar , также установленным в true.

Answer 4

У Джима Маккита есть отличная идея, но он не рассматривает одну вещь, которая может или не может быть проблемой. Вы говорите о компонентах, занимающих много времени для инициализации. Под этим вы подразумеваете раздел initialization или что-то, что происходит позже, например, во время создания ваших форм? Потому что все разделы инициализации выполняются до запуска любого кода в DPR. Если эта часть занимает много времени, вам придется сделать несколько хитрых вещей, чтобы ваш заставка отображалась перед всем этим:

Поместите блок формы как можно ближе к вершине .DPR. (Но не раньше, чем вещи, которые должны идти в первую очередь, как FastMM). Поместите код для отображения заставки в разделе инициализации этого устройства. И убедитесь, что нет никаких модулей с длинными периодами инициализации, которые использует ваш экран-заставка (или что те, которые используют его ... или где-нибудь в дереве зависимостей). И затем надеемся, что это сработает.

Если проблемы замедления не начнутся до тех пор, пока не будет закончен начальный стек инициализации, то следуйте словам Джима.

Answer 5

Проблема блокирования основного потока не решается запуском заставки в отдельном потоке, потому что для обновления экрана потребуется основной поток.

Если заставка не меняется, это не проблема.

Возможно, вам следует обратиться к стороннему поставщику компонентов, потому что такой длинный блок - настоящая проблема.

Answer 6

Я создаю заставку в коде запуска, где всегда наверху, а затем использую frmSplash.Update в соответствующих местах, чтобы убедиться, что он виден и обновлен. Основная форма create - это одно из таких мест, где ее можно назвать.

Проблема в том, что Delphi 2007 предполагает, что первая форма теперь является основной формой, и нет никакой возможности заменить основную форму в базовом коде, поэтому всплески уже не так хороши. Возможно, старое визуальное базовое решение - иметь маленькое быстрое приложение-заставку, которое затем запускает основное приложение - может быть лучше!