Рекурсивные функции в выражениях вычислений - PullRequest
Новая
       19

Рекурсивные функции в выражениях вычислений

5 голосов
/ 29 июня 2010

Сначала немного фона.В настоящее время я изучаю некоторые вещи о монадических парсерных комбинаторах.В то время как я пытался передать функцию 'chainl1' из этой статьи (стр. 16-17), я пришел к такому решению: 

let chainl1 p op = parser {
  let! x = p
  let rec chainl1' (acc : 'a) : Parser<'a> =
      let p' = parser {
          let! f = op
          let! y = p
          return! chainl1' (f acc y)
          }
      p' <|> succeed acc
  return! chainl1' x
}

Я протестировал функцию с некоторыми большимивход и получил StackOverflowException.Теперь мне интересно, возможно ли переписать рекурсивную функцию, которая использует некоторое вычислительное выражение, таким образом, чтобы он использовал хвостовую рекурсию?

Когда я раскрываю вычислительное выражение, я не могу видеть, как это будетбыть вообще возможным. 

let chainl1 p op =
    let b = parser
    b.Bind(p, (fun x ->
    let rec chainl1' (acc : 'a) : Parser<'a> =
        let p' =
            let b = parser
            b.Bind(op, (fun f ->
            b.Bind(p, (fun y ->
            b.ReturnFrom(chainl1' (f acc y))))))
        p' <|> succeed acc
    b.ReturnFrom(chainl1' x)))

Ответы [ 2 ]

6 голосов
/ 29 июня 2010

В вашем коде следующая функция не является хвостовой рекурсивной, потому что - на каждой итерации - она ​​делает выбор между p' или succeed: 

// Renamed a few symbols to avoid breaking SO code formatter
let rec chainl1Util (acc : 'a) : Parser<'a> = 
  let pOp = parser { 
    let! f = op 
    let! y = p 
    return! chainl1Util (f acc y) } 
  // This is done 'after' the call using 'return!', which means 
  // that the 'cahinl1Util' function isn't really tail-recursive!
  pOp <|> succeed acc

В зависимости от вашей реализациииз комбинаторов синтаксического анализа может работать следующее переписывание (я здесь не эксперт, но, возможно, стоит попробовать это): 

let rec chainl1Util (acc : 'a) : Parser<'a> = 
  // Succeeds always returning the accumulated value (?)
  let pSuc = parser {
    let! r = succeed acc
    return Choice1Of2(r) }
  // Parses the next operator (if it is available)
  let pOp = parser {
    let! f = op
    return Choice2Of2(f) }

  // The main parsing code is tail-recursive now...
  parser { 
    // We can continue using one of the previous two options
    let! cont = pOp <|> pSuc 
    match cont with
    // In case of 'succeed acc', we call this branch and finish...
    | Choice1Of2(r) -> return r
    // In case of 'op', we need to read the next sub-expression..
    | Choice2Of2(f) ->
        let! y = p 
        // ..and then continue (this is tail-call now, because there are
        // no operations left - e.g. this isn't used as a parameter to <|>)
        return! chainl1Util (f acc y) }

В общем, шаблон для написания хвостовых рекурсивных функций внутри выражений вычисленийработает.Примерно так будет работать (для выражений вычислений, которые реализованы таким образом, что допускает хвостовую рекурсию): 

let rec foo(arg) = id { 
  // some computation here
  return! foo(expr) }

Как вы можете проверить, новая версия соответствует этому шаблону, а оригинальная - нет.

2 голосов
/ 29 июня 2010

В общем случае можно писать хвосто-рекурсивные вычислительные выражения (см. 1 и 2 ), даже с несколькими привязками let! благодаря механизму 'delay'.

В этом случае, я думаю, последнее утверждение chainl1 - это то, что загоняет вас в угол.

...