Как я могу проверить URL SWF перед загрузкой стилей из if (или обнаружив ошибку)?

Question

Я пытаюсь использовать следующий код для загрузки стилей из внешнего SWF-файла, но получаю сообщение об ошибке ActionScript, когда URL-адрес недействителен:

Error: Unable to load style(Error #2036: Load Never Completed. URL: http://localhost/css/styles.swf): ../css/styles.swf.
at <anonymous>()[C:\autobuild\3.2.0\frameworks\projects\framework\src\mx\styles\StyleManagerImpl.as:858] 


private function loadStyles(): void
{
    try
    {
        var styleEvent:IEventDispatcher = 
            StyleManager.loadStyleDeclarations("../styles.swf");

        styleEvent.addEventListener(StyleEvent.COMPLETE, 
                                                    loadStyle_completeHandler);

        styleEvent.addEventListener(StyleEvent.ERROR, 
                                                    loadStyle_errorHandler);
    }
    catch (error:Error)
    {
        useDefault();
    }
}

private function loadStyle_completeHandler(event:StyleEvent): void
{
    IEventDispatcher(event.currentTarget).removeEventListener(
        event.type, loadStyle_completeHandler);

    goToNextStep();
}

private function loadStyle_errorHandler(event:StyleEvent): void
{
    IEventDispatcher(event.currentTarget).removeEventListener(
        event.type, loadStyle_errorHandler);

    useDefault();
}

Я в основном хочу использовать стили по умолчанию, если пользователь не увидит ошибку, если этот файл не может быть загружен, но я не могу найти способ сделать это.

Answer 1

Интересная проблема. Попробуйте удалить вызов removeEventListener или закомментировать его; в моих кратких тестах оказалось, что обработчик событий вызывался дважды (я не сразу уверен, почему, хотя я подозреваю, что это связано с наследованием стилей), и комментирование этой строки помогло.

Если у вас тот же результат, вы можете сначала попытаться проверить прослушиватель (используя hasEventListener), а не подключать его в функции loadStyles (). Надеюсь, это поможет!

Answer 2

Я отладил источник и обнаружил, что ERROR Event - это , запускаемое дважды. Итак, я просто устанавливаю флаг в первый раз, когда запускается обработчик событий ERROR, и проверяю этот флаг на значение true, прежде чем продолжить:

private var isErrorTriggered:Boolean; // Default is false

private function loadStyle_completeHandler(event:StyleEvent):void
{
    IEventDispatcher(event.currentTarget).removeEventListener(
        event.type, loadStyle_completeHandler);

    goToNextStep();
}

private function loadStyle_errorHandler(event:StyleEvent):void
{
    if (isErrorTriggered)
        return;

    isErrorTriggered = true;

    useDefault();
}

Answer 3

** Не ответ, а обновление:

К вашему сведению, это код ActionScript в источнике mx.styles.StyleManagerImpl, который запускается при вызове StyleManager.loadStyleDeclarations (). Я запустил отладчик и добавил точку останова в строке 858 («throw new Error (errorText);»), и точка останова была обнаружена. Я думаю, что это не должно быть поймано там, но предыдущий IF («if (styleEventDispatcher.willTrigger (StyleEvent.ERROR)))») должен быть выполнен вместо этого.

public function loadStyleDeclarations2(
                    url:String, update:Boolean = true,
                    applicationDomain:ApplicationDomain = null,
                    securityDomain:SecurityDomain = null):
                    IEventDispatcher
{
    var module:IModuleInfo = ModuleManager.getModule(url);

    var readyHandler:Function = function(moduleEvent:ModuleEvent):void
    {
        var styleModule:IStyleModule =
            IStyleModule(moduleEvent.module.factory.create());

        styleModules[moduleEvent.module.url].styleModule = styleModule;

        if (update)
            styleDeclarationsChanged();
    };

    module.addEventListener(ModuleEvent.READY, readyHandler,
                            false, 0, true);

    var styleEventDispatcher:StyleEventDispatcher =
                                    new StyleEventDispatcher(module);

    var errorHandler:Function = function(moduleEvent:ModuleEvent):void
    {
        var errorText:String = resourceManager.getString(
            "styles", "unableToLoad", [ moduleEvent.errorText, url ]);

        if (styleEventDispatcher.willTrigger(StyleEvent.ERROR))
        {
            var styleEvent:StyleEvent = new StyleEvent(
                StyleEvent.ERROR, moduleEvent.bubbles, moduleEvent.cancelable);
            styleEvent.bytesLoaded = 0;
            styleEvent.bytesTotal = 0;
            styleEvent.errorText = errorText;
            styleEventDispatcher.dispatchEvent(styleEvent);
        }
        else
        {
            throw new Error(errorText);
        }
    };

    module.addEventListener(ModuleEvent.ERROR, errorHandler,
                            false, 0, true);

    styleModules[url] =
        new StyleModuleInfo(module, readyHandler, errorHandler);

    // This Timer gives the loadStyleDeclarations() caller a chance
    // to add event listeners to the return value, before the module
    // is loaded.
    var timer:Timer = new Timer(0);
    var timerHandler:Function = function(event:TimerEvent):void
    {
        timer.removeEventListener(TimerEvent.TIMER, timerHandler);
        timer.stop();
        module.load(applicationDomain, securityDomain);
    };

    timer.addEventListener(TimerEvent.TIMER, timerHandler, false, 0, true);

    timer.start();

    return styleEventDispatcher;
}