TCL: рекурсивный поиск в подкаталогах для поиска всех файлов .tcl

Question

У меня есть основной процесс TCL, который поставляет тонны других процедур tcl в другие папки и последующие подкаталоги. Например, в основной процедуре он имеет:

source $basepath/folderA/1A.tcl
source $basepath/folderA/2A.tcl
source $basepath/folderA/3A.tcl
source $basepath/folderB/1B.tcl
source $basepath/folderB/2B.tcl
source $basepath/folderB/3B.tcl

и, кажется, глупо делать это таким образом, когда я всегда знаю, что буду искать все в папке A и папке B. Есть ли функция (или простой способ), которая позволит мне просто получать все файлы .tcl во всей папке?

Answer 1

С tcllib на борту он становится тривиальным:

package require fileutil
foreach file [fileutil::findByPattern $basepath *.tcl] {
    source $file
}

Answer 2

Основываясь на ответе Раманмана, он представляет собой подпрограмму, которая решает проблему с помощью встроенных команд файла TCL и рекурсивно обрабатывает ее по дереву каталогов.

# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles { basedir pattern } {

    # Fix the directory name, this ensures the directory name is in the
    # native format for the platform and contains a final directory seperator
    set basedir [string trimright [file join [file normalize $basedir] { }]]
    set fileList {}

    # Look in the current directory for matching files, -type {f r}
    # means ony readable normal files are looked at, -nocomplain stops
    # an error being thrown if the returned list is empty
    foreach fileName [glob -nocomplain -type {f r} -path $basedir $pattern] {
        lappend fileList $fileName
    }

    # Now look for any sub direcories in the current directory
    foreach dirName [glob -nocomplain -type {d  r} -path $basedir *] {
        # Recusively call the routine on the sub directory and append any
        # new files to the results
        set subDirList [findFiles $dirName $pattern]
        if { [llength $subDirList] > 0 } {
            foreach subDirFile $subDirList {
                lappend fileList $subDirFile
            }
        }
    }
    return $fileList
 }

Answer 3

Возможно, чуть больше не зависит от платформы и использует встроенные команды вместо передачи в процесс:

foreach script [glob [file join $basepath folderA *.tcl]] {
  source $script
}

Повторите для папки B.

Если у вас более строгие критерии выбора и вы не беспокоитесь о работе на других платформах, использование find может быть более гибким.

Answer 4

Та же идея, что и у шленка:

package require Tclx
for_recursive_glob scriptName $basepath *.tcl {
    source $scriptName
}

Если вам нужны только папка A и папка B, а не другие папки в $ basepath:

package require Tclx
for_recursive_glob scriptName [list $basepath/folderA $basepath/folderB] *.tcl {
    source $scriptName
}

Answer 5

Основываясь на предыдущем ответе, эта версия обрабатывает циклы, созданные символьными ссылками, и при этом удаляет дубликаты файлов благодаря символическим ссылкам.

# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles {directory pattern} {

    # Fix the directory name, this ensures the directory name is in the
    # native format for the platform and contains a final directory seperator
    set directory [string trimright [file join [file normalize $directory] { }]]

    # Starting with the passed in directory, do a breadth first search for
    # subdirectories. Avoid cycles by normalizing all file paths and checking
    # for duplicates at each level.

    set directories [list]
    set parents $directory
    while {[llength $parents] > 0} {

        # Find all the children at the current level
        set children [list]
        foreach parent $parents {
            set children [concat $children [glob -nocomplain -type {d r} -path $parent *]]
        }

        # Normalize the children
        set length [llength $children]
        for {set i 0} {$i < $length} {incr i} {
            lset children $i [string trimright [file join [file normalize [lindex $children $i]] { }]]
        }

        # Make the list of children unique
        set children [lsort -unique $children]

        # Find the children that are not duplicates, use them for the next level
        set parents [list]
        foreach child $children {
            if {[lsearch -sorted $directories $child] == -1} {
                lappend parents $child
            }
        }

        # Append the next level directories to the complete list
        set directories [lsort -unique [concat $directories $parents]]
    }

    # Get all the files in the passed in directory and all its subdirectories
    set result [list]
    foreach directory $directories {
        set result [concat $result [glob -nocomplain -type {f r} -path $directory -- $pattern]]
    }

    # Normalize the filenames
    set length [llength $result]
    for {set i 0} {$i < $length} {incr i} {
        lset result $i [file normalize [lindex $result $i]]
    }

    # Return only unique filenames
    return [lsort -unique $result]
}

Answer 6

Вот один из способов:

set includes [open "|find $basedir -name \*.tcl -print" r]

while { [gets $includes include] >= 0 } {
  source $include
}

close $includes

Answer 7

Ответ от Joseph Bui работает хорошо, за исключением того, что он пропускает файлы в исходной папке.

Изменение:

set directories [list]

Для того, чтобы:

set directories [list $directory]

исправить