Назначить класс CSS элементу в XSL

Question

Мой XML-файл выглядит следующим образом:

<worksheet>
<row>
<rowTitle>RT1</rowTitle>
<rowType>yesorno</rowType>
<subLine>subLine1Content</subLine>
<subLine>subLine2Content</subLine>
</row>
<row>
<rowTitle>RT2</rowTitle>
<rowType>operation</rowType>
<subLine>subLine1Content</subLine>
<subLine>subLine2Content</subLine>
<subLine>subLine3Content</subLine>
</row>
.
.
</worksheet>

в моем xsl, при отображении содержимого определенной строки, я хотел бы добавить класс в элемент html, который будет указывать типстрока это.Я попытался использовать xsl: choose и присвоить значение переменной xsl:, но это не сработало.Я пытаюсь отобразить строку как

<ol>
<li class="rowTypeBoolean">
RT1
<ul><li>subLineContent1</li>
<li>subLineContent2</li></ul>
</li>
<li class="rowTypeOptions">
RT2
<ul><li>subLineContent1</li>
<li>subLineContent2</li>
<li>subLineContent3</li></ul>
</li>
.    
.
</ol>

Фрагмент XSL-файла

<xsl:template match="row">
        <li class="rowClass ${className}">
            <xsl:choose>
                <xsl:when test="type = 'YESORNO'">
                    <xsl:variable name="className" select="rowTypeBoolean"/>
                </xsl:when>
                <xsl:when test="type = 'OPTIONS'">
                    <xsl:variable name="className" select="rowTypeOptions"/>
                </xsl:when>
                <xsl:when test="type = 'OPERATION'">
                     <xsl:variable name="className" select="rowTypeOperation"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="className" select="rowTypeOther"/>
                </xsl:otherwise>
            </xsl:choose>
            <span class="rowTitleClass">
                <xsl:value-of select="rowtitle"/>
            </span>
            <br/>
            <ul class="subLineListClass">
                <xsl:apply-templates select="subLine"/>
            </ul>
        </li>
</xsl:template>

Answer 1

Вам необходимо добавить его как атрибут к элементу:

    <li>
        <xsl:choose>
            <xsl:when test="type = 'YESORNO'">
                <xsl:attribute name="className">rowTypeBoolean</xsl:attribute>
            </xsl:when>
            <xsl:when test="type = 'OPTIONS'">
                <xsl:attribute name="className">rowTypeOptions</xsl:attribute>
            </xsl:when>
            <xsl:when test="type = 'OPERATION'">
                <xsl:attribute name="className">rowTypeOperation"</xsl:attribute>
            </xsl:when>
            <xsl:otherwise>
                <xsl:attribute name="className">rowTypeOther"</xsl:attribute>
            </xsl:otherwise>
        </xsl:choose>
    </li>

Answer 2

Самым наивным решением было бы использовать xsl:choose инструкцию, подобную этой:

<li>
    <xsl:attribute name="className"> 
        <xsl:choose> 
            <xsl:when test="type = 'YESORNO'">rowTypeBoolean</xsl:when> 
            <xsl:when test="type = 'OPTIONS'">rowTypeOptions</xsl:when> 
            <xsl:when test="type = 'OPERATION'">rowTypeOperation</xsl:when> 
            <xsl:otherwise>rowTypeOther</xsl:otherwise> 
        </xsl:choose> 
    </xsl:attribute>
</li> 

Другим способом было бы иметь встроенную карту (или через fn:document()), например:

<li class="{$map[@type = current()/type]|$map[not(@type)]}"/>

С этим элементом верхнего уровня

<map:map xmlns:map="map">
    <item type="YESORNO">rowTypeBoolean</item>
    <item type="OPTIONS">rowTypeOption</item>
    <item type="OPERATIONS">rowTypeOperation</item>
    <item>rowTypeOther</item>
</map:map>

<xsl:variable name="map" select="document('')/*/map:map/*" xmlns:map="map"/>

Answer 3

Нет необходимости использовать <xsl:choose> в преобразовании :

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="worksheet">
  <ol>
   <xsl:apply-templates/>
  </ol>
 </xsl:template>

 <xsl:template match="row[rowType='yesorno']">
   <li class="rowTypeBoolean">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row[rowType='operation']">
   <li class="rowTypeOperation">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row[rowType='options']">
   <li class="rowTypeOptions">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row">
   <li class="rowTypeOther">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="subLine[1]">
  <ul>
    <xsl:apply-templates select="../subLine" mode="process"/>
  </ul>
 </xsl:template>

  <xsl:template match="subLine" mode="process">
    <li><xsl:apply-templates/></li>
  </xsl:template>

</xsl:stylesheet>

при применении кпредоставленный XML-документ :

<worksheet>
    <row>
        <rowTitle>RT1</rowTitle>
        <rowType>yesorno</rowType>
        <subLine>subLine1Content</subLine>
        <subLine>subLine2Content</subLine>
    </row>
    <row>
        <rowTitle>RT2</rowTitle>
        <rowType>operation</rowType>
        <subLine>subLine1Content</subLine>
        <subLine>subLine2Content</subLine>
        <subLine>subLine3Content</subLine>
    </row>
</worksheet>

дает требуемый, правильный результат :

<ol>
    <li class="rowTypeBoolean">
        <rowTitle>RT1</rowTitle>
        <rowType>yesorno</rowType>
        <ul>
            <li>subLine1Content</li>
            <li>subLine2Content</li>
        </ul>
        <subLine>subLine2Content</subLine>
    </li>
    <li class="rowTypeOperation">
        <rowTitle>RT2</rowTitle>
        <rowType>operation</rowType>
        <ul>
            <li>subLine1Content</li>
            <li>subLine2Content</li>
            <li>subLine3Content</li>
        </ul>
        <subLine>subLine2Content</subLine>
        <subLine>subLine3Content</subLine>
    </li>
</ol>

Примечание :

1. Используются только простые шаблоны и <xsl:apply-templates> .Следовательно, вероятность совершения ошибки сводится к минимуму.

2. Этот код по сути является расширяемым и обслуживаемым .Если введен новый тип строки, ни один из существующих шаблонов не нужно будет изменять - нужно будет просто добавить новый короткий и простой шаблон, который соответствует элементу row, имеющему дочерний элемент rowType, с новым значением.

3. Отображение между rowType и соответствующим значением атрибута class можно указать в специальном элементе пространства имен глобального уровня и / или переменной (как сделано в решении Алехандро), или даже в отдельном документе XML.Тогда у нас может быть только один шаблон, соответствующий row.