Как я могу сериализовать замыкание в Perl? - PullRequest
Новая
       13

Как я могу сериализовать замыкание в Perl?

6 голосов
/ 02 октября 2010

Я думаю, это лучше всего задать, используя пример: 

use strict;
use warnings;
use 5.010;
use Storable qw(nstore retrieve);

local $Storable::Deparse = 1;
local $Storable::Eval    = 1;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001
nstore( $sub, "/tmp/sub.store" );
$sub = retrieve("/tmp/sub.store");
say $sub->(1); # gives 1

Когда я сбрасываю /tmp/sub.store Я вижу: 

$VAR1 = sub {
            package Storable;
            use warnings;
            use strict 'refs';
            my($y) = @_;
            return $x + $y;
        }

Но $x никогда не определяется в этомк югу.Я ожидаю, что сгенерированный sub_generator саб будет заменен на $x его фактическим значением при генерации.Как мне решить эту проблему?

Обратите внимание, что этот вопрос относится к этому one .

1 Ответ

5 голосов
/ 02 октября 2010

К сожалению, я не думаю, что Storable работает с замыканиями.Однако есть и другие CPAN-модули, которые сериализуют замыкание.Например,Data::Dump::Streamer

use 5.012;
use warnings;
use Data::Dump::Streamer;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001

my $serialised = Dump( $sub )->Out;
my $copy = do {
    my $CODE1 = undef;
    eval $serialised;
    $CODE1;
};

say $copy->(2); # gives 1002
say $sub->(1);  # still gives 1001

Так выглядит сериализованный код при печати здесь say Dump $sub;: 

my ($x);
$x = 1000;
$CODE1 = sub {
           use warnings;
           use strict 'refs';
           BEGIN {
             $^H{'feature_unicode'} = q(1);
             $^H{'feature_say'} = q(1);
             $^H{'feature_state'} = q(1);
             $^H{'feature_switch'} = q(1);
           }
           my($y) = @_;
           return $x + $y;
         };


Обновление

См. Эту ветку Storable and Closures в списке рассылки Perl5-носильщиков.Это подтверждает то, что я думал о Storable и закрытиях.

/ I3az /

...